7

在过去的几周里，我一直在尝试独立学习 Haskell。目前，我正在尝试实现一个愚蠢的小猜谜游戏，其中计算机选择一个随机数，用户尝试猜测它。如果用户错了，程序会告诉用户答案更高或更低，并允许用户猜测，直到他们猜对为止。我已经让它工作了，但我想添加一个功能，以跟踪用户在每场游戏中的猜测次数，并在用户猜对后将该数字报告给用户。

来自命令式背景，自然要做的事情是有一个计数器，每次用户进行猜测时都会增加一个计数器，但在 Haskell 中你不能真正做到这一点（至少它看起来像一切的无状态和不变性会阻止这种情况）。

我玩弄了让 getGuess 和 giveHints 函数接受一个额外参数的想法，该参数表示到目前为止的猜测次数（我们称之为 numGuesses），并且在每次调用这些方法时，传递 (numGuesses+1)。但我无法让它发挥作用（更不用说我什至不知道这是否会奏效）。

我的代码如下。任何建议将不胜感激。我主要是在寻找想法，但也可以随意发布实际代码。另外，如果我的代码很糟糕，请随时告诉我，如果你发现任何令人发指的事情，我该如何改进它（我只在功能上编程了几个星期！）

    import System.Random
    import System.IO
    import Control.Monad

    main = do
        gen <- getStdGen
        let (ans,_) = randomR (1,100) gen :: (Int,StdGen)
        putStrLn $ "I'm thinking of a number between 1 and 100..."
        getGuess ans
        putStrLn "You guessed it in __ guesses!"
        putStr "Play again? "
        hFlush stdout
        desire <- getLine
        when ((desire !! 0) `elem` ['y','Y']) $ do
            putStrLn ""
            newStdGen
            main

    getGuess ans = do   
        putStr "Your guess? "
        hFlush stdout
        guessStr <- getLine
        giveHints ans (read guessStr)

    giveHints ans guess = do
        when (ans /= guess) $ do
           if ans > guess 
               then putStrLn "It's higher." 
               else putStrLn "It's lower."
           getGuess ans

注意：我使用的是 hFlush 标准输出，因为我使用的是行缓冲，没有它，一些交互的顺序就不是人们所期望的。

4

2 回答 2

8

您实际上可以实现您正在考虑的计数方法，但您仍然必须显式地传递状态。但在这种情况下，这根本不是一件麻烦事。事实上，这是一种在辅助函数中经常看到的模式，在这种情况下，实际使用Statemonad 将是多余的。

我所指的模式通常是这样的：

doStuff xs' = go xs' 0
  where
    go (x:xs) n = .. etc ..

这是代码。

import System.Random       (randomRIO)
import Control.Applicative ((<$>))
import Control.Monad       (when)
import Text.Printf         (printf)  

playGame :: Int -> Int -> IO ()
playGame answer curGuesses = do
    putStrLn "What is your guess?"
    putStr   ">"
    guess <- getGuessFromUser
    when (guess /= answer) $ do
        giveHints answer guess
        playGame answer (curGuesses + 1)
    when (guess == answer) $ do
        putStrLn "You guessed it!"
        printf   "You guessed %d times!\n" (curGuesses + 1)

giveHints :: Int -> Int -> IO ()
giveHints answer guess 
    | answer > guess = putStrLn "It's higher!"
    | otherwise      = putStrLn "It's lower!"

getGuessFromUser :: IO Int
getGuessFromUser = do
    read <$> getLine

main :: IO ()
main = do
    answer <- randomRIO (1, 100)
    putStrLn "I'm thinking of a number between 1 and 100."
    playGame answer 0

笔记

  • <$>是fmap
  • 我randomRIO像丹尼尔提到的那样使用，因为我们已经在 IO monad 中。
  • 我不必在 Windows 上使用hSetBuffering或hFlush使用命令提示符来获得正确的输出。然而，YMMV。
于 2012-08-08T02:23:46.510 回答
3

为猜测的数量添加一个额外的参数正是你在功能上做这种事情的方式。

基本的函数式思维模式是，如果您有一个函数需要根据“某物”的不同值表现出不同的行为，那么该某物就是该函数的参数。这是纯洁的一个简单结果；对于相同的输入，函数必须始终返回相同的内容。

当您使用更高级的技术时，有多种方法可以“隐藏”额外参数，从而使您不必显式地编写/传递它们；这基本上正是Statemonad 所做的，而考虑IOmonad 的一种方式是它正在做类似的事情。但是，虽然您是函数式编程的新手，但习惯这种思维模式可能会更有帮助；您通过其参数将信息传递给您正在调用的函数，并通过其参数接收信息。您不能求助于将信息留在某个外部位置（例如计数器的值）的命令技巧，您知道调用的函数将查找它（甚至修改它）。

于 2012-08-08T06:15:19.407 回答