1

我正在尝试编写一个函数来将单词从源内存复制到目标内存。

我已经编写了函数，但我在执行代码时遇到了困难。它给了我execption 4一个错误

.data    
.text      
main:

.setnoreorder      
top: beq $a2,0,done 
lw $t1,($a0) 
sw $t1,($a1) 
add $a0,$a0,4 
add $a1,$a1,4 
j top     
sub $a2,$a2,1


done:   
jr  $ra     #return to the main program 
add $0, $0, $0  #nop

我想编写一个调用此函数的主程序，将 800 个字从地址 0x50000 复制到内存中的 0x90000。但是当我在 $a0-$a2 中添加值并运行代码时它不起作用。有谁知道如何修理它。（我正在将 C 代码转换为 MIPS，这就是我包含 C 标记的原因

干杯

4

3 回答 3

1 
    .text                       # code starts here 
main:                           # required label
    la      $a0,dest            # point to destination
    la      $a1,srce            # point to source
    li      $a2,1000            # move this many words 
    jal     block_copy          # call the routine 
    nop
    li      $v0,10
    syscall

###############################################################################
#   block copy - moves $a3 words from $a1 to $a0
#
#   register usage:
#       $a0 address of destination 
#       $a1 address of source
#       $a2 block size (number of words to move)
#       $v0 return code (0 means no troubles)
#
block_copy:

    move        $v0,$a2         # counter/rc 
bc_loop:
    lw          $t0,0($a1)      # no DMA here
    sw          $t0,0($a0)      # we have to move a word at a time 
    addiu       $a0,$a0,4       # point to next word in destination
    addiu       $a1,$a1,4       # point to next word in source
    addiu       $v0,$v0,-1      # decrement counter 
    bgtz        $v0,bc_loop     # keep on moving if counter is positive 
    jr          $ra             # return to caller
###############################################################################

    .data 
dest:
    .word       9:1000          # destination 1000 words (all zeroes)
srce:
    .word       0:1000          # source 1000 words (all nines)
于 2012-08-06T02:20:56.850 回答
0

那不应该是：

sub $a2,$a2,1
j top
于 2012-08-06T00:25:31.377 回答
0

你在两个地方显示了一个延迟槽，这里

j top     
sub $a2,$a2,1

和这里

done:   
jr  $ra     #return to the main program 
add $0, $0, $0  #nop

但显然不在这里：

top: beq $a2,0,done 
lw $t1,($a0)

也许问题在于，beq 之后的加载实际上是一个延迟槽，并且即使在 $a2 为零（并且采用分支）时也正在执行 - 即使在计数时，您也在 ($a0) 处从内存加载为零 - 可能访问无效内存并导致异常。

于 2012-08-06T01:22:56.703 回答