15

在 C/C++ 中，我通常将指针打印为数组name@dimension。Fortran 的等价物是什么？

4

3 回答 3

16

Fortran 90 使用描述符来表示其数组的维度（形状）并传递假定形状的数组参数。Fortran 中的指针也很特殊——它们只能指向合格的目标。这允许在 Fortran 中比在 C/C++ 中更好的调试器自省。只需使用print arr(index)或其中一个info命令 - 不需要花哨的东西。

示例代码：

program arr
  real, dimension(40) :: stack_array
  real, allocatable, dimension(:), target :: heap_array
  real, dimension(:), pointer :: ptr_array
  integer :: i
  ! Interface required because of the assumed-shape array argument
  interface
    subroutine foo(bar, baz, qux, ptr)
      real, dimension(:) :: bar
      real, dimension(40) :: baz
      real, dimension(*) :: qux
      real, dimension(:), pointer :: ptr
    end subroutine foo
  end interface

  allocate(heap_array(40))

  forall(i = 1:40) stack_array(i) = i
  heap_array = stack_array + 2
  ptr_array => heap_array

  print *, stack_array(1)

  call foo(stack_array, stack_array, stack_array, ptr_array)

  deallocate(heap_array)
end program arr

subroutine foo(bar, baz, qux, ptr)
  real, dimension(:) :: bar
  real, dimension(40) :: baz
  real, dimension(*) :: qux
  real, dimension(:), pointer :: ptr

  print *, bar(1), baz(1), qux(1), ptr(1)
end subroutine foo

使用调试信息编译并运行gdb：

$ gfortran -g -o arr.x arr.f90 && gdb ./arr.x
...
(gdb) info locals
heap_array = (3, 4, 5, 6, 7, 8, 9, 10, 11, 12, ...
ptr_array = (3, 4, 5, 6, 7, 8, 9, 10, 11, 12, ...
stack_array = (1, 2, 3, 4, 5, 6, 7, 8, 9, 10, ...
(gdb) print heap_array
$1 = (3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, ...
(gdb) print ptr_array(3:7)
$2 = (5, 6, 7, 8, 9)
...
(gdb) info args
bar = (1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, ...
baz = (1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, ...
qux = ()
ptr = (3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, ...

由于显而易见的原因，它无法显示假定大小的数组参数的内容，但您可以单独打印每个元素：

(gdb) print qux(1)
$5 = 1
(gdb) print qux(2)
$6 = 2
(gdb) print qux(15)
$7 = 15

请注意，打印数组部分不适用于假定大小的数组参数，因为它们不是由描述符传递并gdb遇到麻烦：

(gdb) print qux(1:8)
$8 = (0, 0, 0, 0, 0, 0, 2.25609053e-43, 0)
(gdb) print qux(2:9)
$9 = (0, 0, 0, 0, 0, 0, 2.25609053e-43, 0)
于 2012-08-03T11:24:57.170 回答
10

我遇到了类似的问题，发现这个和这个链接很有用。

归结为：如果您没有正确版本的 gdb 和 gfortran，则需要执行例如

(gdb) print *((real *)my_array + 2)

或（在我的情况下）

(gdb) print *((real *)my_array + 2)

打印数组的第二个元素。你也可以做

(gdb) print *((real_8 *)my_array + 2)@5

查看数组元素 2、...、2+5。

于 2013-06-14T10:39:27.200 回答
7

这在 gdb 7.7.1 中对我有用：

print A(1)@N

其中 A 是数组，N 是要打印的元素数。对于二维数组：

print A(1,1)@N

我知道这是一个老问题，但谷歌查询“gdb print fortran array”会导致这里。

于 2016-06-30T15:22:20.567 回答