7

我正在使用此代码懒惰地编码列表（取自此SO question）：

import Data.Binary

newtype Stream a = Stream { unstream :: [a] }

instance Binary a => Binary (Stream a) where

    put (Stream [])     = putWord8 0
    put (Stream (x:xs)) = putWord8 1 >> put x >> put (Stream xs)

问题是解码实现并不懒惰：

    get = do
        t <- getWord8
        case t of
            0 -> return (Stream [])
            1 -> do x         <- get
                    Stream xs <- get
                    return (Stream (x:xs))

这在我看来应该是懒惰的，但是如果我们运行这个测试代码：

head $ unstream (decode $ encode $ Stream [1..10000000::Integer] :: Stream Integer)

内存使用量激增。出于某种原因，它想在让我查看第一个元素之前解码整个列表。

为什么这不是懒惰的，我怎样才能让它变得懒惰？

4

1 回答 1

7

它不是懒惰的，因为Getmonad 是一个严格的状态 monad（在binary-0.5.0.2 到 0.5.1.1；它以前是一个懒惰的状态 monad，在binary-0.6.*中它已成为一个延续 monad，我没有分析了该更改的严格性含义）：

-- | The parse state
data S = S {-# UNPACK #-} !B.ByteString  -- current chunk
           L.ByteString                  -- the rest of the input
           {-# UNPACK #-} !Int64         -- bytes read

-- | The Get monad is just a State monad carrying around the input ByteString
-- We treat it as a strict state monad. 
newtype Get a = Get { unGet :: S -> (# a, S #) }

-- Definition directly from Control.Monad.State.Strict
instance Monad Get where
    return a  = Get $ \s -> (# a, s #)
    {-# INLINE return #-}

    m >>= k   = Get $ \s -> case unGet m s of
                             (# a, s' #) -> unGet (k a) s'
    {-# INLINE (>>=) #-}

因此最终的递归

get >>= \x ->
get >>= \(Stream xs) ->
return (Stream (x:xs))

Stream强制在返回之前读取整个内容。

我认为不可能Stream在Get单子中懒惰地解码 a （所以更不用说Binary实例了）。但是您可以使用以下方法编写惰性解码函数runGetState：

-- | Run the Get monad applies a 'get'-based parser on the input
-- ByteString. Additional to the result of get it returns the number of
-- consumed bytes and the rest of the input.
runGetState :: Get a -> L.ByteString -> Int64 -> (a, L.ByteString, Int64)
runGetState m str off =
    case unGet m (mkState str off) of
      (# a, ~(S s ss newOff) #) -> (a, s `join` ss, newOff)

首先编写一个Get返回 a 的解析器Maybe a，

getMaybe :: Binary a => Get (Maybe a)
getMaybe = do
    t <- getWord8
    case t of
      0 -> return Nothing
      _ -> fmap Just get

然后用它来制作一个类型的函数(ByteString,Int64) -> Maybe (a,(ByteString,Int64))：

step :: Binary a => (ByteString,Int64) -> Maybe (a,(ByteString,Int64))
step (xs,offset) = case runGetState getMaybe xs offset of
                     (Just v, ys, newOffset) -> Just (v,(ys,newOffset))
                     _                       -> Nothing

然后你可以Data.List.unfoldr用来懒惰地解码一个列表，

lazyDecodeList :: Binary a => ByteString -> [a]
lazyDecodeList xs = unfoldr step (xs,0)

并将其包装在一个Stream

lazyDecodeStream :: Binary a => ByteString -> Stream a
lazyDecodeStream = Stream . lazyDecodeList
于 2012-07-27T23:26:12.437 回答