0

如何获取 xslt 中元素的值。假设我的xml是这样的，

<comp>
 <link ref=1>1997</link>
 <link ref=2><?LINK 2008?></link>
</comp>

我需要这样的输出，

<comp>
  <link ssref=1/><num>1997</num>
  <link ssref=2/><num>2008</num>
</comp>

如果链接具有价值，我需要获得该价值，如果它具有这样的价值，<?LINK 2008?>我只需要一年。我使用了以下xsl，但它不起作用。

<xsl:template match ="link">
<xsl:element name ="{local-name(.)}">
  <xsl:attribute name ="sshref">
    <xsl:value-of select ="@ref"/>
  </xsl:attribute>
    </xsl:element>
<xsl:if test="text()">
  <xsl:element name ="num">
    <xsl:value-of select ="link"/>
  </xsl:element>
</xsl:if>
</template>

我知道这个 xsl 错误我只是发布一些参考。提前致谢。

4

3 回答 3

3

首先，您的 XML 格式不正确，因为属性应该用撇号或引号括起来，但我猜这可能是一个简单的错字。

至于具体问题是一个处理指令，所以你的xsl:if检查 text() 不会选择这个。

您还遇到了一个问题，<xsl:value-of select="link" />因为您当前的上下文已经在链接元素上，因此这是在寻找另一个链接元素，它是当前元素的子元素。你可能只想做这样的事情

<xsl:value-of select="." />

所以，你可以像这样重写你的模板

<xsl:template match="link">
    <xsl:element name="{local-name(.)}">
        <xsl:attribute name="sshref">
            <xsl:value-of select="@ref"/>
        </xsl:attribute>
        <xsl:if test="text()|processing-instruction()">
            <xsl:element name="num">
                <xsl:apply-templates select="text()|processing-instruction()"/>
            </xsl:element>
        </xsl:if>
    </xsl:element>
</xsl:template>

<xsl:template match="processing-instruction()">
    <xsl:value-of select="."/>
</xsl:template>

然而，值得注意的是，最好避免使用xsl:if元素，而是使用模板匹配的强大功能。试试这个替代的 XSLT。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="link[text()|processing-instruction()]">
      <link>
         <num>
            <xsl:apply-templates select="text()|processing-instruction()"/>
         </num>
      </link>
   </xsl:template>

   <xsl:template match="link/@ref">
      <xsl:attribute name="ssref">
         <xsl:value-of select="."/>
      </xsl:attribute>
   </xsl:template>

   <xsl:template match="processing-instruction()">
      <xsl:value-of select="."/>
   </xsl:template>

   <xsl:template match="@*|node()[not(self::processing-instruction())]">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

应用于以下 XMK 时

<comp>
   <link ref="1">1997</link>
   <link ref="2"><?LINK 2008?></link>
</comp>

以下是输出：

<comp>
   <link sshref="1">
      <num>1997</num>
   </link>
   <link sshref="2">
      <num>2008</num>
   </link>
</comp>

请注意，除非您想要动态命名的元素，否则无需使用xsl: element。

于 2012-07-26T10:45:55.973 回答
2

您可以做的最简单的 XSLT 转换如下所示

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
       <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="link/text() | link/processing-instruction()">
    <num><xsl:value-of select="normalize-space()" /></num>
  </xsl:template>

  <xsl:template match="link/@ref">
     <xsl:attribute name="ssref"><xsl:value-of select="."/></xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

它转变

<comp>
 <link ref="1">1997</link>
 <link ref="2"><?LINK 2008?></link>
</comp>

成想要的结果。

<comp>
 <link ssref="1"><num>1997</num></link>
 <link ssref="2"><num>2008</num></link>
</comp>
于 2012-07-26T11:18:30.997 回答
1

您的 XML 格式不正确，应该是这样的：

<comp>
  <link ref="1">1997</link>
  <link ref="2"><?LINK 2008?></link>
</comp>

然后您可以使用以下 XSLT 来获得您想要的结果：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="/">
    <xsl:element name="comp">
      <xsl:apply-templates/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="comp/link">
    <xsl:element name="{local-name(.)}">
      <xsl:attribute name="sshref"><xsl:value-of select="@ref"/></xsl:attribute>
    </xsl:element>
    <xsl:if test="text()|processing-instruction()">
      <xsl:element name="num">
        <xsl:apply-templates select="text()|processing-instruction()"/>
      </xsl:element>
    </xsl:if>
  </xsl:template>
  <xsl:template match="processing-instruction()">
    <xsl:value-of select="."/>
  </xsl:template>
</xsl:stylesheet>
于 2012-07-26T11:00:04.173 回答