1

SO问题使我想到了以下问题。

如果一个表有 16 行，我想在表中添加一个字段，其中数字 1,2,3,4,5,...,16 随机排列，即在第 1 行的“RndVal”字段中，这可能是2，那么对于第 2 行，它可能是 5，即 16 个整数中的每一个都需要出现一次而不重复。

为什么以下不起作用？理想情况下，我希望看到这个工作，然后看到替代解决方案。

这可以创建表：

IF OBJECT_ID('tempdb..#A') IS NOT NULL BEGIN DROP TABLE #A END
IF OBJECT_ID('tempdb..#B') IS NOT NULL BEGIN DROP TABLE #B END
IF OBJECT_ID('tempdb..#C') IS NOT NULL BEGIN DROP TABLE #C END
IF OBJECT_ID('tempdb..#myTable') IS NOT NULL BEGIN DROP TABLE #myTable END

CREATE TABLE #B (B_ID INT)
CREATE TABLE #C (C_ID INT)

INSERT INTO #B(B_ID) VALUES
    (10),
    (20),
    (30),
    (40)
INSERT INTO #C(C_ID)VALUES
    (1),
    (2),
    (3),
    (4)

CREATE TABLE #A 
    (
    B_ID INT
    , C_ID INT
    , RndVal INT
    )

INSERT INTO #A(B_ID, C_ID, RndVal)  
SELECT 
        #B.B_ID
        , #C.C_ID
        , 0 
FROM #B CROSS JOIN #C;

然后我尝试使用以下内容添加随机列。逻辑是添加 1 到 16 之间的随机数 > 然后有效地覆盖任何与其他数字重复的数字 > 在循环中...

SELECT 
    ROW_NUMBER() OVER(ORDER BY B_ID) AS Row
    , B_ID
    , C_ID
    , RndVal
INTO #myTable
FROM #A

DECLARE @rowsRequired INT = (SELECT COUNT(*) CNT FROM #myTable)
DECLARE @i INT = (SELECT @rowsRequired - SUM(CASE WHEN RndVal > 0 THEN 1 ELSE 0 END) FROM #myTable)--0


DECLARE @end INT = 1
WHILE @end > 0 
    BEGIN

            SELECT @i = @rowsRequired -  SUM(CASE WHEN RndVal > 0 THEN 1 ELSE 0 END) FROM #myTable
            WHILE @i>0
                BEGIN

                    UPDATE x
                    SET x.RndVal = FLOOR(RAND()*@rowsRequired)
                    FROM #myTable x
                    WHERE x.RndVal = 0 

                    SET @i = @i-1
                END 

         --this is to remove possible duplicates
            UPDATE c 
            SET c.RndVal = 0 
            FROM 
                #myTable c
                INNER JOIN 
                    (
                    SELECT RndVal
                    FROM #myTable
                    GROUP BY RndVal 
                    HAVING COUNT(RndVal)>1
                    ) t
                    ON 
                        c.RndVal = t.RndVal

         SET @end = @@ROWCOUNT

    END

TRUNCATE TABLE #A
INSERT INTO #A
SELECT 
    B_ID
    , C_ID
    , RndVal
FROM #myTable

如果原始表有 6 行，那么结果应该是这样的

B_ID|C_ID|RndVal
----------------
    |    | 5 
    |    | 4
    |    | 1
    |    | 6
    |    | 3
    |    | 2
4

3 回答 3

2

坦率地说，我不明白你的代码

这将使用随机数更新每一行，不重复的数字介于 1 和表中的行数之间

UPDATE T
SET SomeCol = T2.X
FROM
   MyTable T
   JOIN
   (
   SELECT
      KeyCol, ROW_NUMBER() OVER (ORDER BY NEWID()) AS X
   FROM 
      MyTable
   ) T2 ON T.KeyCol = T2.KeyCol

这更简洁，但无法测试它是否按预期工作

UPDATE T
SET SomeCol = X
FROM
   (
   SELECT
      SomeCol, ROW_NUMBER() OVER (ORDER BY NEWID()) AS X
   FROM 
      MyTable
   ) T
于 2012-07-24T17:47:43.447 回答
1

当您将 TOP (1)（因为您需要更新第一个 RndVal=0 记录）和 +1（因为否则您的零标记没有任何意义）添加到您的更新时，事情将开始发生变化。但是非常慢（在我相当过时的笔记本电脑上大约需要 40 秒）。这是因为，随着#myTable 被生成的随机数填充，丢失数字的可能性越来越小 - 您通常会重复，并且必须重新开始。

UPDATE top (1) x
SET x.RndVal = FLOOR(RAND()*@rowsRequired) + 1
FROM #myTable x
WHERE x.RndVal = 0

当然，@gbn 有完全有效的解决方案。

于 2012-07-24T18:08:15.877 回答
0

这与上一个答案基本相同，但特定于您的代码：

;WITH CTE As
(
    SELECT B_ID, C_ID, RndVal, 
    ROW_NUMBER() OVER(ORDER BY NewID()) As NewOrder
    FROM #A
)

UPDATE  CTE
SET     RndVal = NewOrder

SELECT * FROM #A ORDER BY RndVal
于 2012-07-24T17:58:22.503 回答