3

我确定以前有人问过这个问题，但我似乎找不到。我使用下面的代码显示来自 MS Access 数据库的图像。但是，我想知道如何执行以下操作：

- 是否可以采取以下程序并以另一种形式“调用”它？

场景：三种形式。三表一库。我通过 TADOTable 组件和 TADOConnection 访问表。

每个表单都有一个按钮 (btnShowImage)，用于显示来自数据库的图片。为了让它当前工作，我需要将函数添加到表单中，然后在 btnShowImage.OnClick 中，添加如下所示的过程。这发生在所有三种形式上。我的问题是：有没有办法让它更有效率。由于将这段代码添加到所有三个表单似乎有点乏味，如果它基本上是相同的（请记住，在过程中，所有三个表单的表名都不同）。有没有更简单的方法（显示图像），而不必在每个表单上使用所有这些代码？

谢谢你的帮助！

代码：

...uses
    JPEG, ADODB, DB

function JpegStartsInBlob(PicField: TBlobField): integer;
var
  bS: TADOBlobStream;
  buffer: Word;
  hx: string;
begin
  Result := -1;
  bS := TADOBlobStream.Create(PicField, bmRead);
  try
    while (Result = -1) and (bS.Position + 1 < bS.Size) do begin
      bS.ReadBuffer(buffer, 1);
      hx := IntToHex(buffer, 2);
      if hx = 'FF' then begin
        bS.ReadBuffer(buffer, 1);
        hx := IntToHex(buffer, 2);
        if hx = 'D8' then
          Result := bS.Position - 2
        else if hx = 'FF' then
          bS.Position := bS.Position - 1;
      end;
    end;
  finally
    bS.Free
  end;
end;

procedure Tfrm3.btnShowImageClick(Sender: TObject);
var
  bS: TADOBlobStream;
  Pic: TJPEGImage;
begin
  bS := TADOBlobStream.Create(table1.FieldByName('Photo')
    as TBlobField, bmRead);
  bS.Seek(JpegStartsInBlob(table1.FieldByName('Photo') as TBlobField),
    soFromBeginning);
  Pic := TJPEGImage.Create;
  Pic.LoadFromStream(bS);
  frmOne.Image1.Picture.Graphic := Pic;
  Pic.Free;
  bS.Free;
end;

代码位于：http ://delphi.about.com/od/database/l/aa030601d.htm

4

1 回答 1

5

如果我有必须从 3 个不同表单上的按钮调用的代码，除了与每个单独表单的上下文有一些特定差异之外，这在所有地方几乎都是相同的，我会做的是获取代码，将其放入单位，并将差异转化为参数。例如：

procedure LoadJPEGImage(field: TBlobField; image: TImage);
var
  bS : TADOBlobStream;
  Pic : TJPEGImage;
begin
  bS := TADOBlobStream.Create(field, bmRead);   
  Pic := TJPEGImage.Create;
  try
    bS.Seek(JpegStartsInBlob(field), soFromBeginning);
    Pic.LoadFromStream(bS);
    image.Picture.Graphic := Pic;
  finally
    Pic.Free;
    bS.Free;
  end;
end;

现在代码不关心表单或其任何细节；它只需要一个 TBlobField 来读取和一个 TImage 来绘制图片，您可以在任意数量的表单上使用它。

于 2012-07-19T21:26:36.427 回答