flash - flash player 11 检查 GPU 加速

Question

Flash 播放器 11 提供了 3D GPU 加速，但并不是每个显卡都能完成这项工作，当出现不受支持的显卡加速时，就会切换到软件。我可以检查是否可以使用硬件加速来自定义我的应用程序。

Answer 1

您必须获得一个Context3D才能查看它driverInfo：

trace("3d mode: " + context3D.driverInfo);

对我来说，这表明：

最容易测试软件渲染的硬件加速 GPU 将由 DirectX 或 OpenGL 指示。

这可以这样实现：

package
{
    import flash.display.Sprite;
    import flash.display.Stage3D;
    import flash.display3D.Context3D;
    import flash.display3D.Context3DRenderMode;
    import flash.events.Event;
    import flash.system.ApplicationDomain;
    import flash.system.Capabilities;

    public class X extends Sprite
    {
        public function X()
        {
            super();

            if (ApplicationDomain.currentDomain.hasDefinition("flash.display.Stage3D"))
            {
                stage.stage3Ds[0].addEventListener(Event.CONTEXT3D_CREATE, onContext3DCreate);
                stage.stage3Ds[0].requestContext3D();
            }
        }

        private function onContext3DCreate(event:Event):void
        {
            // obtain context
            var t:Stage3D = event.target as Stage3D;
            var context3D:Context3D = t.context3D;

            // detect software mode
            if ((context3D.driverInfo == Context3DRenderMode.SOFTWARE)
                || (context3D.driverInfo.indexOf('oftware') > -1))
            {
                trace("Software mode detected!");
            }

            trace("Flash Version: " + Capabilities.version);
            trace("3D mode: " + context3D.driverInfo);
        }

    }
}

对于 GPU 加速的 StageVideo，请收听StageVideoAvailabilityEvent以确认StageVideoAvailability.AVAILABLE。

这可以实现为：

package
{
    import flash.display.Sprite;
    import flash.events.StageVideoAvailabilityEvent;
    import flash.media.StageVideoAvailability;

    public class X extends Sprite
    {
        public function X()
        {
            super();
            stage.addEventListener(StageVideoAvailabilityEvent.STAGE_VIDEO_AVAILABILITY, onStageVideoState);
        }

        private function onStageVideoState(event:StageVideoAvailabilityEvent):void
        {
            if (event.availability == StageVideoAvailability.AVAILABLE)
                trace("available");
        }

    }
}

拥有 StageVideo 后，渲染状态由 指示StageVideoEvent.RENDER_STATE。

var stageVideo = stage.stageVideos[0];
stageVideo.addEventListener(StageVideoEvent.RENDER_STATE, stageVideoStateChange);

function stageVideoStateChange(event:StageVideoEvent):void
{   
    trace("Render State: " + event.status);
}

渲染状态由以下各项派生StageVideoEvent.status并包括：

• VideoStatus.ACCELERATED- 解码和呈现都发生在硬件中。（最棒的表演。）
• VideoStatus.SOFTWARE- 硬件演示，软件解码。（可接受的性能。）
• VideoStatus.UNAVAILABLE- 没有可用于处理视频的 GPU 资源，并且没有任何显示。回退到 Video 对象。