xml - XSLT：基于子节点的属性排序

Question

我想根据孩子的 name 属性对父节点进行排序。

XML 未排序：

<grand-parent>
  <parent>
    <child name="c"/>
    <child_next name="a"/>
  </parent>
  <parent>
    <child name="a"/>
    <child_next name="a"/>
  </parent>
  <parent>
    <child name="b"/>
    <child_next name="a"/>
  </parent>
</grand-parent>

预期输出：

<grand-parent>
  <parent>
    <child name="a"/>
    <child_next name="a"/>
  </parent>
  <parent>
    <child name="b"/>
    <child_next name="a"/>
  </parent>
  <parent>
    <child name="c"/>
    <child_next name="a"/>
  </parent>
</grand-parent>

XSLT 使用中（不工作 - 返回与输入相同的 XML）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes" method="xml" encoding="UTF-8"/>
  <xsl:strip-space  elements="*"/>
  <xsl:template match="node()|@*" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*">
        <xsl:sort select="/grand-parent/parent/child/@name" order="descending" />
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>  
</xsl:stylesheet>

Answer 1

我会从身份转换中排除：

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="grand-parent">
        <xsl:copy>
            <xsl:apply-templates select="parent|@*">
                <xsl:sort select="child/@name" data-type="text"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

输出

<grand-parent>
   <parent>
      <child name="a"/>
      <child_next name="a"/>
   </parent>
   <parent>
      <child name="b"/>
      <child_next name="a"/>
   </parent>
   <parent>
      <child name="c"/>
      <child_next name="a"/>
   </parent>
</grand-parent>