9

Vim 是一个非常高效的编辑器，我每天都喜欢使用它，但我发现在选项卡之间移动花费的时间比它应该的要多。

当我想切换到另一个选项卡时，我经常重复gt或gT多次。Vim 提供了一种更好的方法来访问所需的选项卡 - n+ gt，其中n是选项卡编号。但是要使用它，您应该先计算标签号。如果您打开十几个标签，它很快就会变得无聊。

我认为枚举选项卡会很好。文件名前面每个选项卡上的单个数字，如下所示：

1 Readme | 2 main.c | 3 main.h | 4 process.h

我希望可以通过编辑配置或使用一些插件来配置 vim 来做到这一点。

有没有办法实现它？

4

2 回答 2

6

您可以使用该tabline选项在 vim 的控制台模式下设置选项卡的标签。请参阅帮助，:h setting-tabline其中还显示了一个非常基本的最小示例，您可以根据需要对其进行调整，例如，对于您想要的，我会使用这样的东西：

fu! MyTabLabel(n)
let buflist = tabpagebuflist(a:n)
let winnr = tabpagewinnr(a:n)
let string = fnamemodify(bufname(buflist[winnr - 1]), ':t')
return empty(string) ? '[unnamed]' : string
endfu

fu! MyTabLine()
let s = ''
for i in range(tabpagenr('$'))
" select the highlighting
    if i + 1 == tabpagenr()
    let s .= '%#TabLineSel#'
    else
    let s .= '%#TabLine#'
    endif

    " set the tab page number (for mouse clicks)
    "let s .= '%' . (i + 1) . 'T'
    " display tabnumber (for use with <count>gt, etc)
    let s .= ' '. (i+1) . ' ' 

    " the label is made by MyTabLabel()
    let s .= ' %{MyTabLabel(' . (i + 1) . ')} '

    if i+1 < tabpagenr('$')
        let s .= ' |'
    endif
endfor
return s
endfu
set tabline=%!MyTabLine()
于 2012-07-06T18:22:19.687 回答
2

如果您正在使用gvim：

set guitablabel=(%N)\ %t\ %M

输入:help tabline和:help guitablabel阅读更多内容。

文档中有一个function MyTabLine()。

于 2012-07-06T16:50:22.750 回答