1

有清单

<nodes>
<node attr='1'/>
<node attr='0'/>
<node attr='1'/>
<node attr='1'/>
</nodes>

我需要应用模板所有节点并计算它：

<xsl:apply-templates select='nodes/node'>
<xsl:if test='@attr=1'>
<xsl:number/>
</xsl:if>
</xsl:apply-templates>

但结果不是 123，结果是 134。如何在 xslt-1.0 中修复它？还有另一种设置数字的方法吗？position() 没有帮助，并且

<xsl:apply-templates select='nodes/node[@attr=1]'>
<xsl:if test='@attr=1'>
<xsl:number/>
</xsl:if>
</xsl:apply-templates>

没办法=(((

4

3 回答 3

3

首先，您的 XSLT 中有错误

<xsl:apply-templates select='nodes/node'> 
   <xsl:if test='@attr=1'> <xsl:number/>     
   </xsl:if>
</xsl:apply-templates>

您不能在xsl:apply-templates中有xsl:if。您需要一个匹配的xsl:template并将代码放在那里...

<xsl:apply-templates select="nodes/node" />

<xsl:template match="node">
   <xsl:if test='@attr=1'>
      <xsl:number/>     
   </xsl:if>
<xsl:template>

实际上，您可以在此处取消xsl:if，只需让模板中的测试匹配

<xsl:template match="node[@attr=1]">
    <xsl:number/>     
<xsl:template>

但是要回答您的问题，您可能需要使用xsl:number元素上的count属性来仅计算您想要的元素

<xsl:number count="node[@attr=1]"/>

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <xsl:apply-templates select="nodes/node"/>
   </xsl:template>

   <xsl:template match="node[@attr=1]">
      <xsl:number count="node[@attr=1]"/>
   </xsl:template>

   <xsl:template match="node"/>
</xsl:stylesheet>

应用于您的 XML 时，结果为 123

于 2012-06-29T08:34:31.057 回答
2

上面写着 123 - 这就是你想要的吗？

<xsl:for-each select="nodes/node[@attr='1']">
  <xsl:value-of select="position()"/>
</xsl:for-each>
于 2012-06-29T08:14:40.693 回答
0

目前尚不清楚您要达到什么目的。我认为您需要计算属性设置为 1 的节点数。在这种情况下，请使用count函数：

<xsl:value-of select="count(nodes/node[@attr='1'])" />

如果您需要在匹配条件的子集中输出所需节点的位置，那么for-each可能是要走的路：

<xsl:for-each select="nodes/node[@attr='1']">
    <xsl:value-of select="position()" />
</xsl:for-each>
于 2012-06-29T08:14:56.287 回答