1

我想在 KOL 中将 TBitMap 转换为 PBitMap。

我试过这个，但我得到一张黑色图片作为输出：

function TbitMapToPBitMap (bitmap : TBitMap) : PbitMap;
begin
 result := NIL;
 if Assigned(bitmap) then begin
  result := NewBitmap(bitmap.Width, bitmap.Height);
  result.Draw(bitmap.Canvas.Handle, bitmap.Width, bitmap.Height);
 end;
end;

知道有什么问题吗？我正在使用Delphi7。

感谢您的帮助。

编辑：新代码：

function TbitMapToPBitMap (const src : TBitMap; var dest : PBitMap) : Bool; 
begin
 result := false;
 if (( Assigned(src) ) and ( Assigned (dest) )) then begin
 dest.Draw(src.Canvas.Handle, src.Width, src.Height);
 result := true;
 end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
 TBitMapTest : TBitMap;
 PBitMapTest : PBitMap;
begin
 TBitMapTest := TBitMap.Create;
 TBitMapTest.LoadFromFile ('C:\test.bmp');
 PBitMapTest := NewBitMap (TBitMapTest.Width, TBitMapTest.Height);
 TbitMapToPBitMap (TBitMapTest, PBitMapTest);
 PBitMapTest.SaveToFile ('C:\test2.bmp');
 PBitMapTest.Free;
 TBitMapTest.Free;
end;
4

1 回答 1

3

要回答您的问题，为什么您的目标图像是黑色的；这是因为您将这些目标图像绘制为源图像和黑色它们是因为将NewBitmap图像初始化为黑色。

想要一个TBitmap到KOL怎么复制或者转换PBitmap我只找到了一种方法（可能是我漏掉了KOL里面的这个功能，但是即使是这样，下面代码中使用的方法还是很有效的）。您可以使用 Windows GDI 功能进行位块传输，BitBlt它只是将指定区域从一个画布复制到另一个画布。

下面的代码，当你点击按钮创建VCL和KOL位图实例，将图像加载到VCL位图，调用VCL到KOL位图复制函数，如果这个函数成功，将KOL位图绘制到表单画布并释放两个位图实例：

uses
  Graphics, KOL;

function CopyBitmapToKOL(Source: Graphics.TBitmap; Target: PBitmap): Boolean;
begin
  Result := False;
  if Assigned(Source) and Assigned(Target) then
  begin
    Result := BitBlt(Target.Canvas.Handle, 0, 0, Source.Width, Source.Height,
      Source.Canvas.Handle, 0, 0, SRCCOPY);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  KOLBitmap: PBitmap;
  VCLBitmap: Graphics.TBitmap;
begin
  VCLBitmap := Graphics.TBitmap.Create;
  try
    VCLBitmap.LoadFromFile('d:\CGLIn.bmp');
    KOLBitmap := NewBitmap(VCLBitmap.Width, VCLBitmap.Height);
    try
      if CopyBitmapToKOL(VCLBitmap, KOLBitmap) then
        KOLBitmap.Draw(Canvas.Handle, 0, 0);
    finally
      KOLBitmap.Free;
    end;
  finally
    VCLBitmap.Free;
  end;
end;
于 2012-06-23T16:36:13.587 回答