7

我正在尝试自定义脚本，并且需要使用 perl 从表单中获取 POST 值。我没有 perl 的背景，但这是一件相当简单的事情，所以我想应该不难。

这是我想在 PERL 中使用的 php 版本的代码：

<?php
$download = ($_POST['dl']) ? '1' : '0';
?>

我知道这可能与 PERL 版本完全无关，但它可以帮助我猜出我到底想要做什么。

4

4 回答 4

7

好吧，在这种情况下，请看一下这个简单的代码：这将对您有所帮助：

#!/usr/bin/perl
use strict;
use warnings;
use CGI;
use CGI::Carp qw(fatalsToBrowser);

sub output_top($);
sub output_end($);
sub display_results($);
sub output_form($);

my $q = new CGI;

print $q->header();

# Output stylesheet, heading etc
output_top($q);

if ($q->param()) {
    # Parameters are defined, therefore the form has been submitted
    display_results($q);
} else {
    # We're here for the first time, display the form
    output_form($q);
}

# Output footer and end html
output_end($q);

exit 0;

# Outputs the start html tag, stylesheet and heading
sub output_top($) {
    my ($q) = @_;
    print $q->start_html(
        -title => 'A Questionaire',
        -bgcolor => 'white');
}

# Outputs a footer line and end html tags
sub output_end($) {
    my ($q) = @_;
    print $q->div("My Web Form");
    print $q->end_html;
}

# Displays the results of the form
sub display_results($) {
    my ($q) = @_;

    my $username = $q->param('user_name');
}

# Outputs a web form
sub output_form($) {
    my ($q) = @_;
    print $q->start_form(
        -name => 'main',
        -method => 'POST',
    );

    print $q->start_table;
    print $q->Tr(
      $q->td('Name:'),
      $q->td(
        $q->textfield(-name => "user_name", -size => 50)
      )
    );

    print $q->Tr(
      $q->td($q->submit(-value => 'Submit')),
      $q->td('&nbsp;')
    );
    print $q->end_table;
    print $q->end_form;
}
于 2012-06-18T18:32:13.507 回答
5

风格建议：您几乎不需要将 0 或 1 分配给变量。只需在 bool 上下文中评估值本身。

在CGI.pm (CGI)中，param方法合并了 POST 和 GET 参数，所以我们需要单独检查请求方法：

#!/usr/bin/env perl
use strict;
use warnings FATAL => 'all';
use CGI qw();
my $c = CGI->new;
print $c->header('text/plain');
if ('POST' eq $c->request_method && $c->param('dl')) {
    # yes, parameter exists
} else {
    # no
}
print 'Do not taunt happy fun CGI.';

使用Plack::Request (PSGI) ，除了混合接口 ( ) 之外，您还有不同的 POST ( body_parameters) 和 GET ( ) 方法：query_parametersparameters

#!/usr/bin/env plackup
use strict;
use warnings FATAL => 'all';
use Plack::Request qw();
my $app = sub {
    my ($env) = @_;
    my $req = Plack::Request->new($env);
    if ($req->body_parameters->get_all('dl')) {
        # yes
    } else {
        # no
    }
    return [200, [Content_Type => 'text/plain'], ['Do not taunt happy fun Plack.']];
};
于 2012-06-18T19:13:02.097 回答
0

这是一个很好的起点：CGI.pm 傻瓜指南，CGI 脚本的 Perl 模块。

这将向您展示“......如何获取 POST 值（从提交的表单）并将其分配给变量。”

希望这可以帮助！

于 2012-06-18T18:15:36.827 回答
0

上面的例子有点复杂。下面的代码将 POST 值读入一个变量。您可以从中提取键值。如果它的 GET 则最好使用CGI模块。

#!/usr/bin/perl

my $FormData = '';
read(STDIN, $FormData, $ENV{'CONTENT_LENGTH'});

## Variable $FormData holds all POST values passed

use CGI;
my $cgi = new CGI;
print $cgi->header();
print "$FormData";
于 2017-03-19T18:47:59.010 回答