2

有没有办法在不使用 SecurityPanel.MICROPHONE 的情况下更改 AS3 中的活动麦克风？我的所有尝试都会停止所有麦克风活动，即使是由单击按钮触发的。

如果我做：

var mic:Microphone = Microphone.getMicrophone(index);

我可以收听并获取麦克风活动、级别和 SampleEvents。一切正常。

如果稍后我这样做：

mic = Microphone.getMicrophone(newIndex);

我开始为 mic.activityLevel 获得 -1 并且没有收到 SampleEvents，但我可以通过以下方式获得新麦克风的正确名称

mic.name;

为简单起见，假设 index 和 newIndex 都是经过测试的工作源，并且如果与初始麦克风请求一起传入，则两者都可以工作。

这是否被视为安全风险并且不允许？一旦你初始化了一个麦克风，这就是你所坚持的吗？我已经在空中切换了相机，但那是空中。

*作为旁注，我不能使用 SecurityPanel 来执行此操作，因为如果计算机连接到扬声器，则从 osx 上的 FireFox 访问时可能会出现反馈。我曾尝试在打开窗口之前将所有声音输出降至 0，但一旦 SecurityPanel.MICROPHONE 处于活动状态，音量就会恢复。不幸的是，仅仅要求用户关掉他们的扬声器并不是一种选择。

4

1 回答 1

3

根据我的经验，有两个原因可能导致 activityLevel 报告 -1 ：

1.用户未接受安全权限

这可以通过StatusEvent.STATUS检测到并检查 mic.muted 属性。

mic.addEventListener(StatusEvent.STATUS, onMicrophoneStatus, false, 0, true);

private function onMicrophoneStatus(event:StatusEvent):void
{           
    if (event.code == "Microphone.Unmuted") 
        trace("Microphone access was allowed."); 
    else if (event.code == "Microphone.Muted") 
        trace("Microphone access was denied."); 
}

2.第二个原因似乎更深奥，与两件事有关。麦克风是否进入环回模式；如果麦克风有 *SampleDataEvent.SAMPLE_DATA* 监听器。

我无法真正准确地解释其背后的逻辑，但我想将麦克风发送到环回模式会初始化一些事件逻辑。你甚至可以做mic.setLoopBack(true); mic.setLoopBack(false); .

我希望有人可以解释背景中实际发生的事情。

3.关于面板打开时出现巨大回声的第二个问题，rockabit找到了一个很好的技巧来解决这个问题。您必须将麦克风的 SoundTransform 属性设置为音量为 0 的声音转换对象。这允许您将麦克风保持在环回模式但防止巨大的回声和反馈以及从输出中删除麦克风捕获的声音。

这是供参考的线程： http ://www.rockabit.com/2009/01/14/microphone-activitylevel-in-flash/

最后，这是我用来初始化麦克风的一段代码，即使在交换麦克风时也能正常工作：（为清楚起见，剪掉了）

private function initializeMicrophone(micIndex:int = 0):void
{   
    trace("Initialize mic: "+micIndex);

    var gain:int = 70;
    var rate:int = 44;
    var silence:int = 0;
    var timeout:int = 100;

    this.microphone = Microphone.getEnhancedMicrophone(micIndex);
    mic.addEventListener(StatusEvent.STATUS, onMicrophoneStatus, false, 0, true);
    mic.addEventListener(SampleDataEvent.SAMPLE_DATA, onSampleData);

    mic.gain = gain;
    mic.setSilenceLevel(silence, timeout);
    mic.rate = rate;

    var micXform:SoundTransform = new SoundTransform(0);
    mic.soundTransform = micXform;

    mic.codec = SoundCodec.NELLYMOSER;
    mic.setUseEchoSuppression(true);
    mic.setLoopBack(true);

    var micOptions:MicrophoneEnhancedOptions = new MicrophoneEnhancedOptions();
    micOptions.mode = MicrophoneEnhancedMode.FULL_DUPLEX;
    micOptions.nonLinearProcessing = true;
    micOptions.echoPath = 128;
    mic.enhancedOptions = micOptions;
}

private function onSwapMicrophone():void
{
    if(this.mic.index == 0)
      initializeMicrophone(1);
    else
      initializeMicrophone(0);
}

希望这可以帮助！

-b

于 2012-08-09T17:44:55.840 回答