3

我正在尝试使用 Perl 和 DBI 模块从 SQL Server 数据库中读取数据。我的意图是读取数据并将其打印到文本文件中（逗号分隔）。当我这样做时，我得到这样的结果：

var1,var2,var3
40406,20 ,783
50230,78 ,680
50230,78 ,680
50230,78 ,680
50230,78 ,680

所以第二个变量数据和逗号之间有一个空格。我尝试使用下面的代码对其进行修整，但没有奏效。我应该如何修改我的代码以摆脱那些空格？

我的代码在这里：

#!/bin/perl
use warnings;
use strict;
use DBI;

sub trim;

my $dbs = "dbi:ODBC:DRIVER={SQL Server};SERVER={xxxx}";
my ($username, $password) = ('un', 'pwd');

my $dbh = DBI->connect($dbs, $username, $password)
               or die "Can't connect to $dbs: $DBI::errstr";

my $sth = $dbh->prepare("select var1, var2, var3 from db.dbo.table")
                or die "Can't prepare statement: $DBI::errstr";

$sth->execute();

my $outfile = 'temp.txt';
open OUTFILE, '>', $outfile or die "Unable to open $outfile: $!";

print OUTFILE join(",", @{$sth->{NAME}}), "\n";

while (my @re = $sth->fetchrow_array) {
   print OUTFILE join(",", trim(@re)), "\n";
}

close OUTFILE;

$sth->finish();
$dbh->disconnect();

############## subroutines ##################
sub trim($) {
    my $string = shift;
    $string =~ s/^\s+//;
    $string =~ s/\s+$//;
    return $string;
}
4

3 回答 3

5

您的 trim() 函数不会就地修改列表（也不会处理列表）。

因此，以真正的 TIMTOWTDI 方式，您应该修改函数以返回一个新数组：

sub trimArray {
    my @arr = @_;
    my @rv;
    for my $val (@arr) {
        $val =~ s/^\s+//;
        $val =~ s/\s+$//;
        push @rv, $val;
    }
    return @rv;
}

#and then

print OUTFILE join(",", trimArray(@re)), "\n";

或传递对您的函数的引用，然后就地修改数组

sub trimInPlace {
    my $arrRef = shift;
    for my $val (@$arrRef) {
        $val =~ s/^\s+//;
        $val =~ s/\s+$//;
    }
}

#and then

trimInPlace(\@re); #Note the \
print OUTFILE join(",", @re), "\n";

或使用地图

#!/bin/perl
use warnings;
use strict;
use DBI;

#... the same

while (my @re = $sth->fetchrow_array) {
   print OUTFILE join(",", map { trim($_); } @re), "\n"; #Applies
                                                         #trim() to each element
}

#...

############## subroutines ##################
sub trim { #Don't use prototypes
    my $string = shift;
    $string =~ s/^\s+//;
    $string =~ s/\s+$//;
    return $string;
}

或者尝试使用 chomp，通过修改 $/，它只会删除一个尾随空格，仅此而已。

#!/bin/perl
use warnings;
use strict;
use DBI;

#... the same

my $old_sep = $/;
$/ = " ";
while (my @re = $sth->fetchrow_array) {
   chomp(@re); #Modifies in place, returning number of changes
   print OUTFILE join(",", @re), "\n";
}
$/ = $old_sep;
于 2009-07-08T12:35:08.840 回答
1

您还可以检查 DBD::ODBC 是否支持 ChopBlanks 属性：

my $dbh = DBI->connect($dbs, $username, $password, { ChopBlanks => 1 } )

ChopBlanks 属性修剪任何 CHAR 字段的尾随空格（也就是说，如果您的驱动程序支持它......我不确定 DBD::ODBC 是否支持）。

于 2009-07-09T01:34:19.043 回答
0

为什么该字段有尾随空格？通常这表明数据库模型存在某种问题。除了你的trim()功能，你可能会调查为什么数据是脏的。

于 2009-07-10T15:28:29.457 回答