1

我有一个这样的csv文件

name,sex,age
venu,m,16
test,,22

[编辑]
名称也可以有逗号

"venu,gopal",m,16

我想处理性是否无关紧要并将其保存到另一个文件中。

我有这样的脚本

@Echo Off
For /F "usebackq tokens=1-3  delims=," %%a in (test.csv) Do (
   echo %%a, %%b, %%c >> test-new.csv
)

但是对于第三条记录，我得到 %%b 作为 22 应该是空间。如何解决这个问题？

[编辑2]

我已经按照该链接进行了尝试。我不确定我做错了什么。我遇到了同样的问题。请检查一次。

@echo off
setlocal DisableDelayedExpansion

For /F "usebackq tokens=1-3 delims=" %%x in (C:\somefile.csv) Do (

    setlocal EnableDelayedExpansion
    set "var=%%x"   

    set "var=!var:"=""!"
    set "var=!var:^=^^!"
    set "var=!var:&=^&!"
    set "var=!var:|=^|!"
    set "var=!var:<=^<!"
    set "var=!var:>=^>!"
    set "var=!var:,=^,^,!"
    set var=!var:""="!
    set "var=!var:"=""Q!"
    set "var=!var:,,="S"S!"
    set "var=!var:^,^,=,!"
    set "var=!var:""="!"
    set "var=!var:"Q=!"


    For /F "tokens=1-3  delims=," %%a in ("!var:"S"S=","!") Do (
      endlocal
      echo %%~a, %%~b, %%~c
      setlocal EnableDelayedExpansion
      pause
    )

    endlocal

)
4

2 回答 2

2

这有点棘手，因为多个 delim 将被压缩为一个 delim。

因此，您需要将它们替换为唯一的delim 序列。

@Echo Off
setlocal DisableDelayedExpansion
For /F "usebackq tokens=1-3  delims=" %%a in (test.csv) Do (
    set "line=%%a"
    setlocal EnableDelayedExpansion
    set "line="!line:,=","!""
    For /F "tokens=1-3  delims=," %%a in ("!line!") Do (
        echo %%~a, %%~b, %%~c 
    )
)

这将每一列括在引号中，并且%%~a引号将在稍后被删除

编辑：嵌入式逗号的解决方案

在这种情况下，它与如何拆分 ';'的解决方案略有不同 在 CMD 外壳中

@echo off
setlocal DisableDelayedExpansion

For /F "usebackq tokens=1-3 delims=" %%x in (test.csv) Do (
    set "var=%%x"
    setlocal EnableDelayedExpansion
    set "var=!var:^=^^!"
    set "var=!var:&=^&!"
    set "var=!var:|=^|!"
    set "var=!var:<=^<!"
    set "var=!var:>=^>!"
    set "var=!var:,=^,^,!"
    rem ** This is the key line, the missing quote is intention
    call set var=%%var:""="%%
    set "var=!var:"="Q!"
    set "var=!var:^,^,="C!"
    set "var=!var:,,=,!"
    set "var=!var:""="!"

    set "var="!var:,=","!""
    for /F "tokens=1-3 delims=," %%a in ("!var!") do (      
        endlocal
        set "col1=%%~a"
        set "col2=%%~b"
        set "col3=%%~c"
        setlocal EnableDelayedExpansion
        if defined col1 (
            set "col1=!col1:"C=,!"
            set "col1=!col1:"Q="!"
        )

        if defined col2 (
            set "col2=!col2:"C=,!"
            set "col2=!col2:"Q="!"
        )

        if defined col3 (
            set "col3=!col3:"C=,!"
            set "col3=!col3:"Q="!"
        )
        echo a=!col1!, b=!col2!, c=!col3!
        endlocal
    )
)
于 2012-05-21T13:29:18.830 回答
0

使用像 SSED 这样的字符串编辑器，我通过创建一个临时文件克服了这个问题，在该文件中我用“，-”替换了“，”两次，然后将“-”视为原始文件中的一个空字段。 ..

 ssed "s/,,/,-,/ig;s/,,/,-,/ig" file1.csv > file1.tmp

然后正确分配令牌。如果您需要编辑临时文件，然后返回 CSV，请使用...

 ssed "s/,-,/,,/ig;s/,-,/,,/ig" file1.tmp > file1.csv

这似乎比在飞行中通过令牌替换字符串和具有子例程/等要简单得多。

于 2013-07-08T17:00:42.837 回答