8

我有一个名为 file.txt 的文件，其中包含：

     this is line one ^
     this is line two ^
     this is the last line

我怎样才能把它放到一个环境变量中？

我可以从批处理文件中做到这一点：test.bat

    set LF=^
    [blank line]
    [blank line]
    rem two blank lines needed above
    set multi=Line 1!LF!Line 2!LF!Last line
    echo !multi!

这输出三行：

      Line 1
      Line 2
      Last line

那么如何将 file.txt 放入批处理文件中的 envvar 中呢？

4

2 回答 2

8

正如 dbenham 所说，它也可以用 for/f 完成，但它有点复杂。

简单的 80% 解决方案是

setlocal EnableDelayedExpansion

set "var="
set LF=^


rem *** Two empty lines are required for the linefeed
FOR /F "delims=" %%a in (myFile.txt) do (
  set "var=!var!!LF!%%a"
)
echo !var!

但它失败了：
- 如果一行是空白的，它将被跳过
- 如果一行以;EOL 字符开头
- 如果一行包含!（和插入符号）

但是你可以使用更复杂的解决方案

@echo off
SETLOCAL DisableDelayedExpansion
set "all="
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ aux1.txt"`) do (
    set "line=%%a"
    SETLOCAL EnableDelayedExpansion
    set "line=!line:#=#S!"
    set "line=!line:*:=!"
    for /F "delims=" %%p in ("!all!#L!line!") do (
        ENDLOCAL
        set "all=%%p"
    )
)
SETLOCAL EnableDelayedExpansion
if defined all (
set "all=!all:~2!"
set ^"all=!all:#L=^

!"
set "all=!all:#S=#!"
)
echo !all!

代码做什么？
首先，findstr /n ^^将在每一行前面加上一个行号和一个冒号，比如

1:My first Line
2:; beginning with a semicolon
3:
4:there was an empty line

这解决了空行的问题，并且标准的 EOL 字符;可以被忽略。
要获取该行的内容，将值设置为一个变量，同时禁用延迟扩展，这解决了!和^字符的问题。

去掉行号和冒号，会启用延迟扩展（不，delim:解决不了）。

然后全部#替换为#S，这将首先完成，因为删除该行的前缀可能为空并且替换将失败。
但是我为什么要换？
那是因为我不能在这里插入换行符，因为下面的 FOR/F 会因嵌入换行符而失败，
所以我只添加换行符标记（在这种情况下我使用#L），但文件的内容也可以包含 a #L，但是通过#用#S所有标记 替换所有是唯一的。

在标记之后，使用 关闭/禁用延迟扩展存在问题endlocal，但保留修改后的all和line变量的内容。
这是通过FOR/F-endlocal技巧完成的，因为可以在屏障 %%p后面传输内容。endlocal

然后在阅读完整文件后，我检查是否all已定义，因为对于空文件，它将为空。
然后第一个换行标记 #L将被删除，所有其他标记都将替换为真正的换行字符。
然后将锐利的安全#S器恢复为#.

就是这样，所以即使这个解决方案显然......

于 2012-05-16T18:10:59.427 回答
3

你快到了。您需要阅读每一行文本，然后将该行加上换行符附加到变量中。

可以使用 FOR /F，但如果内容包含!字符，则延迟扩展效果不佳。保留空白行和禁用 EOL 选项也很尴尬。

一个更简单的解决方案是使用 SET /P 来读取行。这种技术的局限性是：

1）它修剪每行的尾随控制字符

2) 文件必须使用 Windows 标准的回车、换行符。它不适用于 Unix 样式的换行符。

3）每行限制读取1023字节（不包括行终止符）

请记住，环境变量只能容纳不到 8 KB 的数据。因此，您只能使用这种技术将非常小的文件加载到变量中。

@echo off
setlocal enableDelayedExpansion
set LF=^


:: Two blank lines above needed for definition of LF - do not remove
set file="test.txt"
set "var="
for /f %%N in ('find /c /v "" ^<%file%') do set lineCnt=%%N
<%file% (
  for /l %%N in (1 1 %lineCnt%) do (
    set "ln="
    set /p "ln="
    set "var=!var!!ln!!lf!"
  )
)
set var
于 2012-05-15T20:46:39.233 回答