3

我正在解析一个 CSV 文件，其中每一行如下所示。

10998,4499,SLC27A5,Q9Y2P5,GO:0000166,GO:0032403,GO:0005524,GO:0016874,GO:0047747,GO:0004467,GO:0015245,,,,,,,,,,,,,,, ,,,,,,,,,,,,,,,,,,,,,,

每行末尾似乎都有逗号。

我想获得第一个术语，在本例中为“10998”，并获得与其相关的 GO 术语的数量。所以我在这种情况下的输出应该是，

输出：

10998,7

但它显示的是 299。我意识到每行总共有 303 个逗号。而且我无法找到删除尾随逗号的简单方法。谁能帮我解决这个问题？

谢谢！

我的代码：

use strict;
use warnings;

open my $IN, '<', 'test.csv' or die "can't find file: $!";
open(CSV, ">GO_MF_counts_Genes.csv") or die "Error!! Cannot create the file: $!\n";
my @genes = ();

my $mf;
foreach my $line (<$IN>) {
    chomp $line;
    my @array = split(/,/, $line);
    my @GO = splice(@array, 4);
    my $GO = join(',', @GO);
    $mf = count($GO);
    print CSV "$array[0],$mf\n";
}

sub count {
    my $go = shift @_;
    my $count = my @go = split(/,/, $go);
    return $count;
}
4

4 回答 4

4

我会使用 juanrpozo 的解决方案进行计数，但如果您仍然想按照自己的方式进行，请使用正则表达式替换删除逗号。

$line =~ s/,+$//;
于 2012-05-12T19:44:06.337 回答
3

我建议使用这种更简洁的方式来编写程序。

请注意，该行my @data = split /,/, $line会丢弃尾随的空字段（@data只有 11 个字段包含您的示例数据），因此无论是否预先删除尾随逗号都会产生相同的结果。

use strict;
use warnings;

open my $in, '<', 'test.csv' or die "Cannot open file for input: $!";
open my $out, '>', 'GO_MF_counts_Genes.csv' or die "Cannot open file for output: $!";

foreach my $line (<$in>) {
  chomp $line;
  my @data = split /,/, $line;
  printf $out "%s,%d\n", $data[0], scalar grep /^GO:/, @data;
}
于 2012-05-12T23:08:05.010 回答
2

你可以grep申请@array

my $mf = grep { /^GO:/ } @array;

假设$array[0]从不匹配/^GO:/

于 2012-05-12T19:23:45.120 回答
-1

对于您的每一行：

foreach my $line (<$IN>) {
    my ($first_term) = ($line =~ /(\d+),/);
    my @tmp = split('GO', " $line ");
    my $nr_of_GOs = @tmp - 1;
    print CSV "$first_term,$nr_of_GOs\n";
}
于 2012-05-12T19:43:27.647 回答