6

我正在尝试在 Racket 中编写 OpenCV FFI 并到达需要有效操作数组的地步。但是，我使用 Racket FFI 访问数组的所有尝试都导致代码效率非常低。有没有办法使用 FFI 快速访问 C 数组？

在 Racket 中，这种类型的操作相当快，即：

(define a-vector (make-vector (* 640 480 3)))
(time (let loop ([i (- (* 640 480 3) 1)])
    (when (>= i 0)
      ;; invert each pixel channel-wise
      (vector-set! a-vector i (- 255 (vector-ref a-vector i)))
      (loop (- i 1)))))
->  cpu time: 14 real time: 14 gc time: 0

现在，在 OpenCV 中，有一个名为的结构IplImage，如下所示：

typedef struct _IplImage
{
    int  imageSize;             /* sizeof(IplImage) */
    ...
    char *imageData;        /* Pointer to aligned image data.*/
}IplImage;

该结构在 Racket 中定义如下：

(define-cstruct _IplImage
    ([imageSize _int]
     ...
     [imageData _pointer]))

cvLoadImage现在我们使用如下函数加载图像：

(define img
  (ptr-ref
   (cvLoadImage "images/test-image.png" CV_LOAD_IMAGE_COLOR)
   _IplImage))

imageData可以通过以下方式访问指针：(define data (IplImage-imageData img)))

现在，我们要操作data，而我能想到的最有效的方法是使用指针：

(time (let loop ([i (- (* width height channels) 1)]) ;; same 640 480 3
    (when (>= i 0)
      ;; invert each pixel channel-wise
      (ptr-set! data _ubyte i (- 255 (ptr-ref data _ubyte i)))
      (loop (- i 1)))))
-> cpu time: 114 real time: 113 gc time: 0

与原生 Racket 向量的速度相比，这非常慢。我还尝试了其他方法，例如_array，_cvector它们甚至达不到使用指针的速度，除了用 C 语言编写一个一流的函数，该函数获得一个运行整个数组的函数。这个 C 函数被编译成一个库并使用 FFI 绑定在 Racket 中。然后，可以将 Racket 过程传递给它并应用于数组的所有元素。速度与指针相同，但仍不足以继续将 OpenCV 库移植到 Racket。

有一个更好的方法吗？

4

2 回答 2

7

我尝试了 Eli 建议的方法，结果成功了！这个想法是使用一个字节串。由于在这种情况下数组的大小是已知的，(make-sized-byte-string cptr length)因此可以使用：

(define data (make-sized-byte-string (IplImage-imageData img)
                                     (* width height channels)))

这导致运行时间接近 Racket 的原生向量：

(time (let loop ([i (- (* 640 480 3) 1)])
    (when (>= i 0)
      ;; invert each pixel channel-wise
      (bytes-set! data i (- 255 (bytes-ref data i)))
      (loop (- i 1)))))
-> cpu time: 18 real time: 18 gc time: 0

谢谢你，伊莱。

于 2012-05-09T00:44:34.940 回答
4

使用字节串（通过）设置整个事情可能会更好_bytes，但这是一个非常粗略的猜测。最好在邮件列表上问这个问题......

于 2012-05-08T01:08:09.803 回答