1

我们每 300 毫秒从服务器向客户端发送球的坐标。我们必须插入坐标以使移动平滑。这是代码（AS3）：

private function run(event:Event):void
{
    // Current frame ball position
    var currentPosition:Point = new Point(this.x, this.y);

    // Vector of the speed
    _velocity = _destinationPoint.subtract(currentPosition);

    // Interpolation
    // Game.timeLapse - time from last package with coordinates (last change of destinationPoint)
    // stage.frameRate - fps
    _velocity.normalize(_velocity.length * 1000 / Game.timeLapse / stage.frameRate);

    // If ball isn't at the end of the path, move it
    if (Point.distance(currentPosition, _destinationPoint) > 1) {
        this.x += _velocity.x;
        this.y += _velocity.y;
    } else {
        // Otherwise (we are at the end of the path - remove listener from this event
        this.removeEventListener(Event.ENTER_FRAME, run);
        this.dispatchEvent(new GameEvent(GameEvent.PLAYER_STOP));
    }
}

问题描述如下图：

在此处输入图像描述

  • 红点 - 目的地点

  • 黑线 - 从当前点到目的地的线，没有标准化

  • 绿色点缀 - 球的路径

也许有一种方法可以使移动更顺畅但更准确？

4

2 回答 2

1
  1. 如果您想精确地为三个点插入路径步骤，则需要使用二次贝塞尔曲线数学来计算曲线上距起点的任何给定距离的任何位置。你需要它来沿着曲线获得相等的步长，你在你的照片上。这相当棘手，因为当您使用多项式形式的贝塞尔曲线方程时，对于相等的参数增量，您不会沿着曲线获得相等的距离。

    二次贝塞尔曲线参数多项式

    因此，您需要将贝塞尔曲线视为抛物线段（实际上就是这样），并且可以将任务重新表述为“沿着等长的步长沿着抛物线步进”。这仍然很棘手，但幸运的是有一个解决方案：

    http://code.google.com/p/bezier/

    我多次使用这个库（沿着抛物线等步走），它对我来说非常好用。

  2. 您很可能希望在任意一组点之间进行插值。如果是这种情况，您可以使用拉格朗日近似。

    下面是我对拉格朗日近似的简单实现。（谷歌搜索它肯定会给你更多。）你提供具有任意数量的已知函数值的逼近器，它可以为介于两者之间的任何参数值生成平滑函数的值。

--

package org.noregret.math 
{
    import flash.geom.Point;
    import flash.utils.Dictionary;

    /**
     * @author Michael "Nox Noctis" Antipin
     */
    public class LagrangeApproximator {

        private const points:Vector.<Point> = new Vector.<Point>();
        private const pointByArg:Dictionary = new Dictionary();

        private var isSorted:Boolean;

        public function LagrangeApproximator()
        {
        }

        public function addValue(argument:Number, value:Number):void
        {
            var point:Point;
            if (pointByArg[argument] != null) {
                trace("LagrangeApproximator.addValue("+arguments+"): ERROR duplicate function argument!");
                point = pointByArg[argument];
            } else {
                point = new Point();
                points.push(point);
                pointByArg[argument] = point;
            }
            point.x = argument;
            point.y = value;
            isSorted = false;
        }

        public function getApproximationValue(argument:Number):Number
        {
            if (!isSorted) {
                isSorted = true;
                points.sort(sortByArgument);
            }
            var listLength:uint = points.length;
            var point1:Point, point2:Point;
            var result:Number = 0;
            var coefficient:Number;
            for(var i:uint =0; i<listLength; i++) {
                coefficient = 1;
                point1 = points[i];
                for(var j:uint = 0; j<listLength; j++) {
                    if (i != j) {
                        point2 = points[j];
                        coefficient *= (argument-point2.x) / (point1.x-point2.x);
                    }
                }        
                result += point1.y * coefficient;
            }
            return result;
        }

        private function sortByArgument(a:Point, b:Point):int
        {
            if (a.x < b.x) {
                return -1;
            }
            if (a.x > b.x) {
                return 1;
            }            
            return 0;
        }

        public function get length():int
        {
            return points.length;            
        }

        public function clear():void
        {
            points.length = 0;
            var key:*;
            for (key in pointByArg) {
                delete pointByArg[key];
            }
        }
    }
}
于 2012-05-04T11:08:57.330 回答
0

您可以在每个刻度上发送多个坐标。或者与每个点一起发送一些额外的属性，也许说它是否是球反弹的点，或者是否可以平滑。

与发送、处理和接收的开销相比，在一个事务中发送一系列点将为您提供更高的准确性，并且不会增加太多的数据包大小。

于 2012-05-04T11:07:40.837 回答