18

我有一个带有列表的文件，并且需要制作一个将每一行与另一行进行比较的文件。例如，我的文件有这个：

AAA  
BBB  
CCC  
DDD  
电子电气设备

我希望最终列表看起来像这样：

AAA BBB  
AAA CCC  
AAA DDD  
AAA 电子电气设备  
BBB CCC  
BBB DDD  
BBB 电子电气设备  
CCC DDD  
CCC 电子电气设备  
DDD 电子电气设备

我第一次尝试在 Perl 中执行此操作，但遇到了一些麻烦。我知道你需要制作一个数组，然后拆分它，但在那之后我遇到了一些麻烦。

4

7 回答 7

30

使用算法::组合。基于迭代器的方法比一次生成所有内容更可取。

#!/usr/bin/env perl

use strict; use warnings;
use Algorithm::Combinatorics qw(combinations);

my $strings = [qw(AAA BBB CCC DDD EEE)];

my $iter = combinations($strings, 2);

while (my $c = $iter->next) {
    print "@$c\n";
}

输出：

AAA BBB
AAA CCC
AAA DDD
AAA 电子电气设备
BBB CCC
BBB DDD
BBB 电子电气设备
CCC DDD
CCC 电子电气设备
DDD 电子电气设备
于 2012-04-24T14:48:22.723 回答
9

使用递归来写这个很简单。

此代码示例演示。

use strict;
use warnings;

my $strings = [qw(AAA BBB CCC DDD EEE)];

sub combine;

print "@$_\n" for combine $strings, 5;

sub combine {

  my ($list, $n) = @_;
  die "Insufficient list members" if $n > @$list;

  return map [$_], @$list if $n <= 1;

  my @comb;

  for my $i (0 .. $#$list) {
    my @rest = @$list;
    my $val  = splice @rest, $i, 1;
    push @comb, [$val, @$_] for combine \@rest, $n-1;
  }

  return @comb;
}

编辑

抱歉-我正在生成排列而不是组合。

这段代码是正确的。

use strict;
use warnings;

my $strings = [qw(AAA BBB CCC DDD EEE)];

sub combine;

print "@$_\n" for combine $strings, 2;

sub combine {

  my ($list, $n) = @_;
  die "Insufficient list members" if $n > @$list;

  return map [$_], @$list if $n <= 1;

  my @comb;

  for (my $i = 0; $i+$n <= @$list; ++$i) {
    my $val  = $list->[$i];
    my @rest = @$list[$i+1..$#$list];
    push @comb, [$val, @$_] for combine \@rest, $n-1;
  }

  return @comb;
}

输出

AAA BBB
AAA CCC
AAA DDD
AAA EEE
BBB CCC
BBB DDD
BBB EEE
CCC DDD
CCC EEE
DDD EEE
于 2012-04-24T16:20:30.910 回答
7

看看Math::Combinatorics - 在列表上执行组合和排列

从 CPAN 复制的示例：

use Math::Combinatorics;

  my @n = qw(a b c);
  my $combinat = Math::Combinatorics->new(count => 2,
                                          data => [@n],
                                         );

  print "combinations of 2 from: ".join(" ",@n)."\n";
  print "------------------------".("--" x scalar(@n))."\n";
  while(my @combo = $combinat->next_combination){
    print join(' ', @combo)."\n";
  }

  print "\n";

  print "permutations of 3 from: ".join(" ",@n)."\n";
  print "------------------------".("--" x scalar(@n))."\n";
  while(my @permu = $combinat->next_permutation){
    print join(' ', @permu)."\n";
  }

  output:
combinations of 2 from: a b c
  ------------------------------
  a b
  a c
  b c

  permutations of 3 from: a b c
  ------------------------------
  a b c
  a c b
  b a c
  b c a
  c a b
  c b a
于 2012-04-24T14:33:36.017 回答
1

这是一个黑客使用glob：

my @list = qw(AAA BBB CCC DDD EEE);

for my $i (0..$#list-1) {
    print join "\n", glob sprintf "{'$list[$i] '}{%s}",
          join ",", @list[$i+1..$#list];
    print "\n";
}

输出：

AAA BBB
AAA CCC
AAA DDD
AAA EEE
BBB CCC
BBB DDD
BBB EEE
CCC DDD
CCC EEE
DDD EEE

PS 您可能想要使用Text::Glob::Expandor String::Glob::Permutemodules 而不是 plainglob()以避免在当前工作目录中匹配文件的警告。

于 2012-04-24T15:08:12.333 回答
1

我对以下 Perl 模块进行了基准测试：

  1. 数学::组合
  2. 算法::组合学
  3. 商业银行

基准测试包括执行 OP 要求的操作，组合 2 个项目，但将单词集增加到 10,000 个，而不是最初请求的 5 个（AAA BBB CCC DDD EEE）。

Math::Combinatorics 的测试脚本

#!/usr/bin/env perl
use strict; use warnings;
use Math::Combinatorics;
my $strings = [qw(AAA BBB CCC DDD EEE) x 2000];
my $iter = new Math::Combinatorics (count => 2, data => $strings);
while (my @c = $iter->next_combination) {
    print "@c\n";
}

这每秒产生约 53,479 个组合。

Algorithm::Combinatorics 的测试脚本

#!/usr/bin/env perl
use strict; use warnings;
use Algorithm::Combinatorics qw(combinations);
my $strings = [qw(AAA BBB CCC DDD EEE) x 2000];
my $iter = combinations($strings, 2);
while (my $c = $iter->next) {
    print "@$c\n";
}

这每秒产生约 861,982 个组合。

Cmb 的测试脚本

#!/usr/bin/env perl
use strict; use warnings;
use Cmb;
my $strings = [qw(AAA BBB CCC DDD EEE) x 2000];
my $cmb = new Cmb { size_min => 2, size_max => 2 };
$cmb->cmb_callback($#$strings + 1, $strings, sub {
    print "@_\n";
    return 0;
});

这每秒产生约 2,940,882 个组合。

但如果你只需要打印组合，Cmb 实际上可以比上面更快地完成。

#!/usr/bin/env perl
use strict; use warnings;
use Cmb;
my $strings = [qw(AAA BBB CCC DDD EEE) x 2000];
my $cmb = new Cmb { size_min => 2, size_max => 2 };
$cmb->cmb($#$strings + 1, $strings);

这每秒产生约 3,333,000 个组合。

基准测试是在 CentOS Linux 版本 7.7.1908 (Core) 上使用dpv在内核 3.10.0-1062.1.1.el7.x86_64 x86_64 上使用 Perl 5.16.3 在 Intel(R) Xeon(R) CPU E5-2699 v4 @ 上执行的2.20GHz

于 2019-12-06T03:52:18.147 回答
0
  1. 取第一个字符串
  2. 从下一个位置迭代数组到结束
    1. 将下一个字符串附加到原始字符串
  3. 取下一个字符串并返回步骤 2
于 2012-04-24T14:32:36.740 回答
0

怎么样：

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dump qw(dump);

my @in = qw(AAA BBB CCC DDD EEE);
my @list;
while(my $first = shift @in) {
    last unless @in;
    my $rest = join',',@in;
    push @list, glob("{$first}{$rest}");
}
dump @list;

输出：

(
  "AAABBB",
  "AAACCC",
  "AAADDD",
  "AAAEEE",
  "BBBCCC",
  "BBBDDD",
  "BBBEEE",
  "CCCDDD",
  "CCCEEE",
  "DDDEEE",
)
于 2012-04-24T14:34:40.217 回答