vba - 使用lotusscript计算excel中单元格的总和

Question

我有一个表格，在表格中我有一个包含 excel 文件的对象（工作表）。然后我有一个按钮可以计算工作表中字段的总和，并在表单的字段中显示它的总和。我该如何编码？想法是这样的

总计 = 总和 (A2:A51)

doc.total = totalr

Answer 1

如果您在将要从 Notes 客户端使用的表单上执行此操作，并且运行 Notes 客户端的计算机具有 Excel，那么您可以使用 VBA。只需将文件提取到用户的硬盘驱动器，用 Excel 打开它，在列底部添加一个单元格并在那里放置一个 SUM() 函数，获取该新单元格的值，更新 UIDOC 中的字段，然后擦除临时文件。

下面的代码假定您有一个表单，其中包含一个名为“excelfile”的 RichText 字段（包含 Excel 文件）、一个名为“Sum”的字段，该字段将包含 Excel 文件中的总和值，以及一个包含代码的按钮。此外，必须将文档与附件一起保存，代码才能正常工作。

希望能帮助到你。

Sub Click(Source As Button)

On Error Goto errorhandler

Dim s As New NotesSession
Dim ws As New NotesUIWorkspace
Dim uidoc As NotesUIDocument
Set uidoc = ws.CurrentDocument
Dim doc As NotesDocument
Set doc = uidoc.Document
Dim rtitem As NotesRichTextItem
Dim isfileopen As Boolean

Dim filename As String, rows As Double, cols As Double, colToSum As String, c As Integer
Dim xlApp As Variant, xlWorkbook As Variant, xlSheet As Variant, pathname As String

isfileopen = False

'convert column letter to number
colToSum = "A"
c = Asc(colToSum) - 64

'extract file
pathname = s.GetEnvironmentString( "Directory", True ) & "\"
Set rtitem = doc.GetFirstItem("excelfile")
If Not (doc.HasEmbedded) Then
    Msgbox "There are no file attachments on this document"
    Goto ExitGracefully
End If  
Forall o In rtitem.EmbeddedObjects
    If ( o.Type = EMBED_ATTACHMENT ) Then
        filename = pathname & o.Name            
        Call o.ExtractFile( filename )          
    End If
End Forall

'open file
Print "Opening file " & filename & "..."
Set xlApp = CreateObject("Excel.Application") 
xlApp.Workbooks.Open filename
isfileopen = True

'get sheet
Print "Gathering data ..."
Set xlWorkBook = xlApp.ActiveWorkbook 
Set xlSheet = xlWorkBook.ActiveSheet 
xlSheet.Cells.SpecialCells(11).Activate
rows = xlApp.ActiveWindow.ActiveCell.Row 
cols = xlApp.ActiveWindow.ActiveCell.Column 

'add a row and put the sum() formula there
Print "Computing sum with Excel..."
xlSheet.Cells( rows+1, c ).value = "=SUM(" & colToSum & "1:" & colToSum & Cstr(rows) & ")"

'update UI doc
Call uidoc.FieldSetText( "Sum", Cstr(xlSheet.Cells( rows+1, c ).value) )

exitgracefully:

'close excel
Print "Closing Excel..."
If Not xlWorkbook Is Nothing Then
    xlWorkbook.Close False 
End If
If Not xlApp Is Nothing Then
    xlApp.DisplayAlerts = False
    xlApp.Quit
    Set xlApp = Nothing 
End If 

If isfileopen Then
    'remove temp file
    Print "Removing " & filename
    Kill filename
End If

'done
Print "Done"

Exit Sub
errorhandler:
Msgbox Error & " line " & Erl
Exit Sub
End Sub