delphi - 如何拦截（检测）粘贴命令到 TMemo 中？

Question

如何在将文本粘贴到之前捕获粘贴命令并更改剪贴板的文本TMemo，但是，在粘贴之后，剪贴板中的文本必须与更改前相同？

例如，剪贴板有文本'Simple Question'，进入的文本TMemo是'Симплe Qуeстиoн'，然后剪贴板中的文本就像更改之前一样，'Simple Question'。

Answer 1

派生一个从 'TMemo' 继承的新控件以拦截WM_PASTE消息：

type
  TPastelessMemo = class(TMemo)
  protected
    procedure WMPaste(var Message: TWMPaste); message WM_PASTE;
  end;

uses
  clipbrd;

procedure TPastelessMemo.WMPaste(var Message: TWMPaste);
var
  SaveClipboard: string;
begin
  SaveClipboard := Clipboard.AsText;
  Clipboard.AsText := 'Simple Question';
  inherited;
  Clipboard.AsText := SaveClipboard;
end;

如果您想完全禁止任何粘贴操作，请清空 WMPaste 处理程序。

Answer 2

这是 Sertac 出色答案的替代方法，即覆盖控件的 WndProc：

// For detecting WM_PASTE messages on the control
OriginalMemoWindowProc: TWndMethod;
procedure NewMemoWindowProc(var Message: TMessage);
//...

// In the form's OnCreate procedure:
// Hijack the control's WindowProc in order to detect WM_PASTE messages
OriginalMemoWindowProc := myMemo.WindowProc;
myMemo.WindowProc := NewMemoWindowProc;
//...

procedure TfrmMyForm.NewMemoWindowProc(var Message: TMessage);
var
    bProcessMessage: Boolean;
begin
    bProcessMessage := True;
    if (Message.Msg = WM_PASTE) then
        begin
        // Data pasted into the memo!
        if (SomeCondition) then
            bProcessMessage := False;   // Do not process this message any further!
        end;

    if (bProcessMessage) then
        begin
        // Ensure all (valid) messages are handled!
        OriginalMemoWindowProc(Message);
        end;
end;