1

我有一个格式如下的文本文件：

(title,price,id#)

CD1,11.00,111111
CD2,12.00,222222
CD3,13.00,333333
CD4,14.00,444444
CD5,15.00,555555
CD6,16.00,666666

如果给我 id# 和新价格，那么更改相应 CD 价格的最佳方法是什么？

我确定它与获取行和拆分它有关，但我不确定我如何只编辑一行而不弄乱整个文件。

4

3 回答 3

2

好的，现在我们知道它是一个短文件，生活变得容易多了：

  • 使用将文件加载到行数组中File.ReadAllLines
  • 找到正确的行string.Split用于将每行拆分为组成部分，并检查 ID。
  • 找到正确的行后，将其替换为完整的新行
  • 将文件写回File.WriteAllLines

这应该足以让你继续前进。

于 2012-04-11T07:28:28.760 回答
2

你不能在不重写整个文件的情况下重写一行（除非这些行恰好是相同的长度）。对于这么小的文件，最简单的方法可能是更改内存中的行，然后将所有内容重写到文件中：

Dim idToFind = "444444"
Dim newPrice = "100"
Dim lines = IO.File.ReadAllLines(path)
For i = 0 To lines.Length - 1
    Dim line = lines(i)
    Dim fields = line.Split(","c)
    If fields.Length > 2 Then
        Dim id = fields(2)
        If id = idToFind Then
            Dim title = fields(0)
            lines(i) = String.Format("{0},{1},{2}", title, newPrice, id)
            Exit For
        End If
    End If
Next
IO.File.WriteAllLInes(path, lines)
于 2012-04-11T07:35:44.157 回答
0

如果它只是一个包含 25 行的文件，您可以执行一个简单的输入-转换-输出例程并更新每行的价格。

像这样的东西（使用 Streamreader / writer ）。

Sub UpdatePrice(ByVal pricesToUpdate As Dictionary(Of Integer, String), ByVal inputPath As String)
    If Not IO.File.Exists(inputPath) Then Return
    Try
        Using inputStream = New IO.StreamReader(inputPath, System.Text.Encoding.UTF8, True)
            Using outputStream = New IO.StreamWriter(inputPath + ".tmp", False, System.Text.Encoding.UTF8)
                While Not inputStream.EndOfStream
                    Dim inputLine = inputStream.ReadLine
                    Dim content = inputLine.Split(","c)
                    If Not content.Length >= 3 Then
                        outputStream.WriteLine(inputLine)
                        Continue While
                    End If
                    Dim id As Integer
                    If Not Integer.TryParse(content(2), id) Then
                        outputStream.WriteLine(inputLine)
                        Continue While
                    End If
                    If Not pricesToUpdate.ContainsKey(id) Then
                        outputStream.WriteLine(inputLine)
                        Continue While
                    End If
                    content(1) = pricesToUpdate(id)
                    outputStream.WriteLine(String.Join(",", {content(0), content(1), content(2)}))
                End While
            End Using
        End Using
        If IO.File.Exists(inputPath + ".tmp") Then
            IO.File.Delete(inputPath)
            IO.File.Move(inputPath + ".tmp", inputPath)
        End If
    Catch ex As IO.IOException
        If IO.File.Exists(inputPath + ".tmp") Then IO.File.Delete(inputPath + ".tmp")
    End Try
End Sub
于 2012-04-11T07:37:46.913 回答