9

我最近发现了一篇文章，它提供了一个解决方案，让 stderr 的文本输出在 Linux (bash) 中具有不同的颜色

他们创建了以下 bash 脚本脚本

#!/bin/bash
{ $* 2>&1>&3|sed 's,.*,\x1B[33m&\x1B[0m,'>&2;} 3>&1

这会导致输出在来自 stderr 时打印黄色文本。stdout 仍然打印相同的颜色。

该脚本保存在 $PATH 上名为 color 的目录中。这允许我使用 make 或 scons 运行脚本，它会将 stderr 中的所有文本以黄色显示。（可以通过将 33m 更改为 31m 使文本变为红色）

color make CPU=x64

这对于在编译时查找错误非常有用。

是否有类似的脚本可用于 Windows cmd shell？

注意：如果有帮助，我已经在我的 Windows 计算机上安装了 sed。

4

3 回答 3

6

关于 Windows 的 cmd.exe 下对 ANSI 转义码的支持，请参见ansicon。将重定向逻辑转换为 cmd.exe 语法后，我准备了以下color.bat文件：

@Echo Off
(((%* 1>&3) 2>&1) | "c:\Program Files (x86)\GnuWin32\bin\sed.exe" "s,.*,\x1B[33m&\x1B[0m," 1>&2) 3>&1

不幸的是，流混合在一起（在某些行中，stdout 和 stderr 中的字符在单行中混合在一起）。也许这种行为取决于使用的 sed.exe 版本，所以试一试。

如果这不起作用，请考虑使用最小的cygwin安装。我测试了你的color.sh脚本，我能够启动一个 .bat 文件，它可以正常工作而无需混合流。我使用的语法是：

./color.sh cmd /c test.bat
于 2012-04-12T06:46:15.837 回答
4

我设计了一种使用纯 Batch 命令获得等效解决方案的方法，即没有 Ansi、没有 sed.exe 等，只使用 findstr：

any_command 2>&1 1>&3 | findstr /N /A:4E "^"

在这种情况下，不同的颜色不会被赋予来自 stderr 的整行，而只是赋予 findstr 提供的行号，然而，对于所述要求来说应该足够了。我将很快编写一个小的辅助 .exe 程序，它将以另一种颜色显示整个 stderr 行。

于 2012-04-24T04:55:56.840 回答
2

@MBu，@gnash117

我重命名为color，co因为COLOR是一个 Windows 命令，我将其扩展为：

:: color output - Displays stderr output in different color
::
:: Credits to MBu and gnash117 at http://stackoverflow.com/questions/10095886/change-text-output-color-on-windows-for-stderr#10118710
:: 
:: Requires:
::   - http://sourceforge.net/projects/mingw/files/MSYS/
::   - http://adoxa.altervista.org/ansicon/
::   - http://www.autohotkey.com/
::
@echo off

if "%1"=="" goto :Help

:: 1;31 ... intense red foreground (see https://github.com/adoxa/ansicon/blob/master/sequences.txt for more colors)
:: \x07 ... BEL, but doesn't work :-(
(((%* 1>&3) 2>&1) | sed "s/.*/\x07\x1B[1;31m&\x1B[0m/" 1>&2) 3>&1
goto :EOF

:Help
setlocal
::------------------------------------------------
:: Adapt these in pairs according to your likings
set invokeKeys=[Shift]+[Enter]
set invokeHotkeys=+Enter
set invokeAfterRemoveKeys=[Alt]+[Enter]
set invokeAfterRemoveHotkeys=!Enter
set removeKeys=[Alt]+[c]
set removeHotkeys=!c
::-----------------------------------------------
set invokeText=invokes the entered command after preceding it with '%0 '
set invokeAfterRemoveText=invokes the entered command after removing the first three characters from the beginning
set removeText=removes the first three characters from the command line
echo Colors a command's stderr output as defined in %~f0
echo Usage:
echo   - Preceed a command with '%0 ' (e.g.: 'co dir not.existing.file' will show the resulting error message in a different color)
echo   - If the AutoHotkey script below is active:
echo     - %invokeKeys% ... %invokeText%
echo     - %invokeAfterRemoveKeys% ... %invokeAfterRemoveText%
echo     - %removeKeys% ... %removeText%
echo(
echo       The latter two are useful when using the command line history and having used %invokeKeys% before.
echo(
echo     Enabled by AutoHotkey script:
echo(
echo       #IfWinActive ahk_class ConsoleWindowClass
echo       ; %invokeText%
echo       %invokeHotkeys%::Send {Home}%0 {Enter}
echo       ; %invokeAfterRemoveText%
echo       %invokeAfterRemoveHotkeys%::SendInput {Home}{Del 3}{Enter}
echo       ; %removeText%
echo       %removeHotkeys%::SendInput {Home}{Del 3}{End}
echo       #IfWinActive
endlocal
:EOF
于 2014-08-03T00:01:57.493 回答