5

这些天我正在学习设计模式。有很多关于编程设计模式的文档，但我对闭包设计模式很感兴趣。

我找到了 Venkat Subramaniam 关于Java 和 Groovy 中的设计模式的演示文稿，并根据我自己的经验提取了该演示文稿中涉及闭包和其他模式的一些模式。

执行环绕方法

操作前后需要执行的一对操作。

def operations(closure) {
    println "Open"
    closure()
    println "Close"
}

operations { println "Operation" }

===> Open
===> Operation
===> Close

可插拔行为

指定对象在运行时的行为。

def selectValues(number, closure) {
    def list = []
    1.upto(number) {
        if (closure(it)) list << it
    }
    return list
}

assert [2, 4, 6, 8, 10] == selectValues(10) { it % 2 == 0 }  // even
assert [1, 3, 5, 7, 9]  == selectValues(10) { it % 2 != 0 }  // odd

迭代器模式

允许顺序访问元素。

def listNumbers(closure) {
    (0..5).each { closure it }
}

listNumbers {
    if (it < 3) println "$it is a little number"
    else println "$it is a big number"
}

===> 0 is a little number
===> 1 is a little number
===> 2 is a little number
===> 3 is a big number
===> 4 is a big number
===> 5 is a big number

动态条件执行

创建并执行条件操作。

def greet(user, successClosure, failClosure) {
    if (isAdmin(user)) successClosure()
    else failClosure()
}

greet(user, { println "Hi Admin!" }, { println "Hello User" })

我想了解更多闭包设计模式。有没有关于这个话题的参考？随意用你最喜欢的编程语言编写一个新模式。

更新

我写了一篇关于这个主题的帖子（Groovy 和 Ruby，但内容相同）：
闭包设计模式
闭包设计模式。红宝石版

4

3 回答 3

11

我认为您将闭包与 lambda/匿名函数混淆了？

闭包是具有绑定变量的词法上下文。简而言之，如果您从函数内部定义函数，则内部函数可以访问外部函数中定义的变量。在这种情况下，“词汇上下文”是外部函数。

Lambda是没有变量赋值的函数。例如，在 Ruby 中，您可以将块传递给函数，而函数可以仅使用yield关键字在内部调用它。在 JavaScript 中，您可以定义一个函数并同时将其作为参数传递。你的例子就是这样。

一等函数是另一回事，它们是可以像常规对象一样传递的函数。您可以将它们作为参数传递给函数调用并保存对它们的引用。这就像 Ruby 的Proc. 在 JS 中，所有的函数都是一等的，所有的函数都是对象。

在 JavaScript 中，我们可以用一个愚蠢的例子来说明所有 3 个：

function foo(func) {
  func();
}
var bar = function() {    // bar is a first-class function
  var i = 5;
  foo(function() {        // this is the anonymous function (lambda)
    console.log(i);       // i is the closure-bound variable
  });
}
foo(bar);   // Prints 5

因此，这使您的问题令人困惑。闭包是一种语言特性，而不是一种设计模式。有很多设计模式的实现可以使用闭包或 lambda 或模或构造函数或其他任何东西，正如您通过这些示例向自己展示的那样。虽然这些都不是经典的设计模式，但我不确定我是否会这样称呼它们。也许我会称它们为糖。

Java 可以实现各种设计模式，但没有这些特性。很多这类事情都是通过接口完成的，这是一种完全不同的语言特性。

于 2012-04-04T00:23:48.087 回答
1

正如人们所说，这些并不是真正的“模式”，并且是特定于 Groovy 的，但是闭包的另外两个用途是：

1. 可组合性

def sum    = { Collection a -> a.sum() }
def first2 = { Collection a -> a.take( 2 ) }

def take2andAdd = sum << first2

println take2andAdd( [ 1, 2, 3, 4 ] ) // Prints 3

2.咖喱

def add = { a, b -> a + b }
def add2 = add.curry( 2 )

println add2( 3 ) // Prints 5

当然，这些可以组合：

def square = { a -> a * a }
def add = { a, b -> a + b }
def add2 = add.curry( 2 )

def add2andSquare = square << add2

println add2andSquare( 3 ) // prints 25
于 2012-04-04T07:42:52.913 回答
1

我同意其他回应，因为谈论闭包设计模式并没有真正的意义（尤其是当您似乎真的在谈论一流的功能时；））。我认为您真正想要了解的重点是在实现设计模式时如何使用诸如一流函数、lambda 和闭包之类的工具。尽管它特定于 Groovy，但您可能会发现查看此页面很有用：http: //groovy.codehaus.org/Design+Patterns+with+Groovy

例如，“Loan my Resource Pattern”展示了如何以与“Execute Around Method”模式非常相似的方式使用闭包，而“Visitor Pattern”也很好地利用了闭包，但并未包含在你的清单。

于 2012-04-10T12:08:13.283 回答