6

我正在使用为 arm-eabi 编译的 GCC/G++ 开发嵌入式应用程序。由于资源限制，我试图禁用标准 C++ 异常处理。我正在使用“-fno-exceptions -nostartfiles -ffreestanding”编译代码。

当一个类的全局实例存在，并且该类包含另一个类的实例作为成员时，就会链接到很多异常处理代码。这不会那么糟糕，除了它也带来了很多stdio 的东西，比如 printf、fopen、fclose 和其他 FILE 函数。这个应用程序没有文件系统，即使有，这些函数也会浪费太多的代码空间。

我知道即使使用 -fno-exceptions，G++ 也会在使用异常的运算符 new 中链接，因为该库没有使用非异常的运算符 new（new(nothrow) 除外）。我为 operator new 和 delete 创建了替换，它们链接到输出以及不需要的标准库函数。

令我困惑的是，我没有在任何地方调用 new。只有当一个全局对象包含另一个对象时，所有这些代码才会链接到其中。

例如：

class UartA {
...
private:
  Ringbuffer* rxbuf;
};

class UartB {
...
private:
  Ringbuffer rxbuf;
};

如果创建了 UartA 的全局实例，则不会链接异常处理、operator new 和 stdio 内容。这就是我想要的。

如果创建了 UartB 的全局实例（其中 rxbuf 是实例而不是指针），则会链接不需要的代码。

UartA 和 UartB 都不使用 operator new、exceptions 或 stdio。它们的区别仅在于 rxbuf 的类型。

你能建议如何防止链接额外的代码吗？另外，为什么这与 UartB 相关联，而不是 UartA？

4

3 回答 3

6

因为您基本上是在做操作系统开发人员为获得独立的 c 或 c++ 环境所做的事情。您可能只想研究使用自定义链接器脚本。您只需要小心，因为诸如全局构造函数之类的事情不再自动发生......但是您也不会得到任何您没有明确要求的东西（并且编写代码来调用全局构造函数并不难）。这是我的操作系统中的链接器脚本。

OUTPUT_FORMAT("elf32-i386")
ENTRY(start)

virt = 0xc0100000; /* 3.1 gig */
phys = 0x00100000; /* 1 meg */

SECTIONS
{ 
    .text virt : AT(phys) 
    {
        code = .; _code = .; __code = .;
        *(.text)
        *(.gnu.linkonce.t*)
        . = ALIGN(4096); 
    }

    .rodata : AT(phys + (rodata - code))
    {
        rodata = .; _rodata = .; __rodata = .;
        *(.rodata*)
        *(.gnu.linkonce.r*)
        __CTOR_LIST__ = .;
        LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2) 
        *(.ctors) 
        LONG(0) 
        __CTOR_END__ = .; 

        __DTOR_LIST__ = .; 
        LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2) 
        *(.dtors) 
        LONG(0) 
        __DTOR_END__ = .; 
        . = ALIGN(4096); 
    }

    .data : AT(phys + (data - code))
    {
        data = .; _data = .; __data = .;    
        *(.data)
        *(.gnu.linkonce.d*)
        . = ALIGN(4096); 
    }

    .tbss : AT(phys + (tbss - code)) 
    {
        tbss = .; _tbss = .; __tbss = .;
        *(.tbss)
        *(.tbss.*)
        . = ALIGN(4096); 
    }

    .bss : AT(phys + (bss - code)) 
    {
        bss = .; _bss = .; __bss = .;
        *(.bss)
        *(.bss.*)
        *(COMMON)
        *(.gnu.linkonce.b*)
        . = ALIGN(4096); 
    }

    end = .; _end = .; __end = .;
}

它可能比您需要的更多（将部分对齐到 4k 边界，所有符号都在 > 3GB 标记处），但它是一个很好的起点。

你可以像这样使用它：

ld -T link_script.ld *.o -lc -o appname

如果这是您想要的，“-lc”也应该链接到 libc 中。

于 2009-06-15T21:15:41.580 回答
5

我认为你能得到的最接近的是编译和链接 -fno-exceptions 和 -fno-rtti。如果有更好的方法来摆脱其余部分，我会很高兴自己听到。

至于摆脱新的，尝试-nostdlib。

于 2009-06-15T20:40:37.187 回答
0

您可以尝试捕获 new 以查看它是否真的被调用了。

在某些情况下，新可能会隐式发生，例如复制构造。

您可以通过稍微不同的方式编写代码来删除这些。

http://www.linuxtopia.org/online_books/programming_books/thinking_in_c++/Chapter11_013.html

于 2009-06-15T21:08:06.607 回答