5

这是（或多或少）一个相关问题：Delphi - Populate an imagelist with icons at runtime 'destroys' contrast。

我已经测试了@TOndrej答案。但似乎我需要启用视觉样式（XP Manifest）才能使其正常工作（将使用 Windows 通用控件的 6.0 版 - 我现在不想要）。我在运行时通过ExtractIconEx和添加图标ImageList_AddIcon。

显然设置ImageList.Handle为使用系统图像列表句柄，不需要XP 清单。因此，当我使用系统图像列表显示文件列表（带有TListView）时，即使是我在 D3 中写回的旧程序也会正确显示 alpha 混合图标。

我在徘徊系统图像列表有什么特别之处，它是如何创建的，所以它在所有情况下都支持 alpha 混合？我想不通。这是一些示例代码：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ImgList, StdCtrls, ShellAPI, ExtCtrls, Commctrl;

type
  TForm1 = class(TForm)
    ImageList1: TImageList;
    PopupMenu1: TPopupMenu;
    MenuItem1: TMenuItem;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    FileName: string;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
// {$R WindowsXP.res}

procedure TForm1.FormCreate(Sender: TObject);
begin
  PopupMenu1.Images := ImageList1;
  FileName := 'C:\Program Files\Mozilla Firefox\firefox.exe';
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  IconPath: string;
  IconIndex: Integer;
  hIconLarge, hIconSmall: HICON;
begin
  IconPath := FileName;
  IconIndex := 0; // index can be other than 0

  ExtractIconEx(PChar(IconPath), IconIndex, hIconLarge, hIconSmall, 1);

  Self.Refresh; // erase form
  DrawIconEx(Canvas.Handle, 10, 10, hIconSmall, 0, 16, 16, 0,
    DI_IMAGE or DI_MASK); // this will draw ok on the form

  // ImageList1.DrawingStyle := dsTransparent;
  ImageList1.Handle := ImageList_Create(ImageList1.Width, ImageList1.Height,
    {ILC_COLORDDB} ILC_COLOR32 or ILC_MASK, 0, ImageList1.AllocBy);
  ImageList_AddIcon(ImageList1.Handle, hIconSmall);

  MenuItem1.ImageIndex := 0;

  DestroyIcon(hIconSmall);
  DestroyIcon(hIconLarge);

  PopupMenu1.Popup(Mouse.CursorPos.X, Mouse.CursorPos.Y);
end;

procedure TForm1.Button2Click(Sender: TObject);
// using sys image-list will work with or without Manifest
type
  DWORD_PTR = DWORD;
var
  ShFileINfo :TShFileInfo;
  SysImageList: DWORD_PTR;
  FileName: string;
begin
  SysImageList := ShGetFileInfo(nil, 0, ShFileInfo, SizeOf(ShFileInfo),
    SHGFI_SYSICONINDEX OR SHGFI_SMALLICON);

  if SysImageList = 0 then Exit;
  ImageList1.Handle := SysImageList;
  ImageList1.ShareImages := True;

  if ShGetFileInfo(PChar(FileName), 0, ShFileInfo, SizeOf(ShFileInfo),
    SHGFI_SYSICONINDEX OR SHGFI_ICON OR SHGFI_SMALLICON) <> 0 then
  begin
    MenuItem1.ImageIndex := ShFileInfo.IIcon;
    Self.Refresh; // erase form
    DrawIconEx(Canvas.Handle, 10, 10, ShFileInfo.hIcon, 0, 16, 16, 0,
      DI_IMAGE or DI_MASK);
    DestroyIcon(ShFileInfo.hIcon); // todo: do I need to destroy here? 

    PopupMenu1.Popup(Mouse.CursorPos.X, Mouse.CursorPos.Y);
  end;      
end;

end.

禁用视觉样式：

在此处输入图像描述

启用视觉样式：

在此处输入图像描述

一种解决方法是使用插入器类或子类TImageList并覆盖DoDraw ，如此处所示，但我真正想知道的是如何创建与系统图像列表相同的图像列表。

注意：我知道TPngImageList并且不想在这种情况下使用它。

编辑： @David 的回答（和评论）是准确的：

您必须显式链接到 ImageList_Create (v6)，否则它会在模块加载时隐式链接并绑定到 v5.8

示例代码（不使用激活上下文 API）：

function ImageList_Create_V6(CX, CY: Integer; Flags: UINT; Initial, Grow: Integer): HIMAGELIST;
var
  h: HMODULE;
  _ImageList_Create: function(CX, CY: Integer; Flags: UINT;
    Initial, Grow: Integer): HIMAGELIST; stdcall;
begin
  // TODO: find comctl32.dll v6 path programmatically
  h := LoadLibrary('C:\WINDOWS\WinSxS\x86_Microsoft.Windows.Common-Controls_6595b64144ccf1df_6.0.2600.5512_x-ww_35d4ce83\comctl32.dll');
  if h <> 0 then
  try
    _ImageList_Create := GetProcAddress(h, 'ImageList_Create');
    if Assigned(_ImageList_Create) then
      Result := _ImageList_Create(CX, CY, Flags, Initial, Grow);
  finally
    FreeLibrary(h);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ...
  ImageList1.Handle := ImageList_Create_V6(ImageList1.Width, ImageList1.Height,
    ILC_COLOR32 or ILC_MASK, 0, ImageList1.AllocBy);
  ...
end;

Edi2：@David 的示例代码，显示了它是如何通过 Activation Context API 正确完成的。

4

1 回答 1

5

图像列表控件有两个版本。v5.8版本和v6版本。系统镜像列表是系统拥有的共享组件，使用v6版本。它在任何其他方面都没有什么特别之处，它只是一个普通的 v6 图像列表。在您的应用中，您的图像列表是 v5.8 还是 v6，具体取决于您是否包含清单。但系统拥有的图像列表始终是 v6。

我不知道您为什么不想在您的应用程序中使用 v6 通用控件。但是有了这个约束，您可以在创建图像列表时使用激活上下文 API 在本地使用 v6 通用控件。这将解决您的问题，并让您的应用程序的其余部分使用 v5.8 通用控件。

于 2012-03-30T06:42:44.830 回答