perl - 当使用 Perl 的 File::Find 什么是限制搜索深度的快速简单的方法？

Question

我希望能够将 Perl 的File::Find目录深度（低于指定的搜索）限制到指定的目录和它下面的 1 和 2 个子目录。

如果可能的话，我希望能够同时枚举文件。

它必须使用绝对路径。

Answer 1

这个perlmonks 节点解释了如何从 GNU 的 find 中实现 mindepth 和 maxdepth。

基本上，他们计算目录中斜杠的数量，并使用它来确定深度。然后，预处理函数将仅返回深度小于 max_depth 的值。

my ($min_depth, $max_depth) = (2,3);

find( {
    preprocess => \&preprocess,
    wanted => \&wanted,
}, @dirs);

sub preprocess {
    my $depth = $File::Find::dir =~ tr[/][];
    return @_ if $depth < $max_depth;
    return grep { not -d } @_ if $depth == $max_depth;
    return;
}

sub wanted {
    my $depth = $File::Find::dir =~ tr[/][];
    return if $depth < $min_depth;
    print;
}

根据您的情况量身定制：

use File::Find;
my $max_depth = 2;

find( {
    preprocess => \&preprocess,
    wanted => \&wanted,
}, '.');

sub preprocess {
    my $depth = $File::Find::dir =~ tr[/][];
    return @_ if $depth < $max_depth;
    return grep { not -d } @_ if $depth == $max_depth;
    return;
}

sub wanted {
    print $_ . "\n" if -f; #Only files
}

Answer 2

File::Find::find这是另一个解决方案，它通过计算返回的目录数量来确定当前深度File::Spec->splitdir，这应该比计算斜杠更便携：

use strict;
use warnings;

use File::Find;

# maximum depth to continue search
my $maxDepth = 2;

# start with the absolute path
my $findRoot = Cwd::realpath($ARGV[0] || ".");

# determine the depth of our beginning directory
my $begDepth = 1 + grep { length } File::Spec->splitdir($findRoot);

find (
  {
    preprocess => sub
      { @_ if (scalar File::Spec->splitdir($File::Find::dir) - $begDepth) <= $maxDepth },
    wanted => sub
      { printf "%s$/", File::Spec->catfile($File::Find::dir, $_) if -f },
  },
  $findRoot
);