3

我试图在 Windows 批处理脚本中处理一个文本文件，但我遇到了一些看起来像是 FOR 循环中 31 个令牌的限制。我在下面的代码中隔离了这个问题：

@ECHO OFF
SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35

FOR /F "tokens=31* delims= " %%i IN ("%DATA%") DO (
    ECHO [%%i]
    ECHO [%%j]
)
ECHO.
FOR /F "tokens=32* delims= " %%i IN ("%DATA%") DO (
    ECHO [%%i]
    ECHO [%%j]
)

输出是：

[31]
[32 33 34 35]

[01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35]
[%j]

我期待这个：

[31]
[32 33 34 35]

[32]
[33 34 35]

希望我没有做错什么，我在 FOR 命令的帮助中找不到这个限制。我正在使用 Windows XP。除了截断部分数据之外，您是否知道任何解决方法？

谢谢你。

4

6 回答 6

4

我想出了一个解决方案。它并不优雅，但它解决了我的问题。当命令行解释器无法进一步处理令牌时，我将数据的剩余部分传递给 CALL :label 命令。这是一个例子：

@ECHO OFF

SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100

FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO  1st token: %%i
    ECHO 31th token: %%j
    CALL :processdatatokens32-62 %%k
)

:processdatatokens32-62
SET DATA=%*
FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO 32nd token: %%i
    ECHO 62th token: %%j
    CALL :processdatatokens63-83 %%k
)
GOTO :EOF

:processdatatokens63-83
SET DATA=%*
FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO 63th token: %%i
    ECHO 93th token: %%j
)
GOTO :EOF

输出是：

 1st token: 01
31th token: 31
32nd token: 32
62th token: 62
63th token: 63
93th token: 93
于 2009-06-12T10:24:45.333 回答
1

来自for /?：

%i 在 for 语句中显式声明，%j 和 %k 通过 tokens= 选项隐式声明。您可以通过 tokens= 行指定最多 26 个标记，前提是它不会导致尝试声明高于字母 'z' 或 'Z' 的变量。请记住，FOR 变量是单字母、区分大小写、全局的，并且您在任何时候都不能有超过 52 个活动。

于 2009-06-11T12:40:28.840 回答
0

记号是算作一个块的最小语法单位。Windows 95/98/ME 中的批处理命令行最大限制为 64 个令牌。再多的话，命令行会Bad command or file name报错。

这就是为什么您在 DATA 中可能仅限于 31 个。

于 2009-06-11T12:45:07.050 回答
0

循环遍历 DATA 数组的方法不止一种：

@ECHO OFF
setlocal ENABLEDELAYEDEXPANSION
SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101

for /l %%a in (0,3,150) do @echo %%a data: !data:~%%a,2!

这仅因为 %DATA% 数组中的两个字符变量而成为可能。正如您将看到的，现在限制为 99 个字符，而不是 31 个。当您达到第 100 个及以上时，该数字将被截断。

抢

于 2009-06-18T22:32:23.367 回答
0

我为批处理创建了一个打字机功能（只是为了好玩），也遇到了这个限制。下面是一个精简的版本，向您展示我是如何解决这个问题的。从命令行执行时，您最多可以使用 8,191 个字符，包括空格分隔符。使用变量时，最大长度为 32,767。

@echo off
::#############################################################################
 :_typeWriter <stringVariable> <skipLinefeed>
::#############################################################################
::
:: Copyleft Denny Lenselink 2018
::

%= Set local environment =%
( call ) & 2>nul setlocal EnableDelayedExpansion || exit /b 99

:: Set vars
set "_CNT=0" && set "_LEN=0" && set "_STR= %~1" && set "_TOT=0"

:_typeWriter_Loop
set /a "_CNT+=1"

:: 31 tokens limit fix. Cut the used part of the string and set counter to 1
if !_CNT! equ 32 ( set "_CNT=1" && set "_STR=!_STR:~%_TOT%!" && set "_TOT=0" )

:: Go through string (seeking words)
for /f "tokens=%_CNT% delims= " %%* in ( "%_STR%" ) do (

    :: Set word var
    set "_WRD=#%%*"

    :: Calculate word length
    for /l %%I in ( 12, -1, 0 ) do (

        set /a "_LEN|=1<<%%I"

        for %%J in ( !_LEN! ) do ( if "!_WRD:~%%J,1!"=="" set /a "_LEN&=~1<<%%I" )
    )

    :: Strip first char (used before to calculate correct word length)
    set "_WRD=!_WRD:~1!"

    :: Count chars including spaces
    set /a "_TOT=!_TOT!+!_LEN!+1"

    :: Type word or use echo
    <nul set /p "=!_WRD! "

    :: Do a loop
    goto _typeWriter_Loop
)

:: No linefeed when specified
if "%~2"=="" echo.

endlocal
exit /b

执行：C:\Temp>typewriter "this is a test that works"

结果：

this is a test that works

将行更改<nul set /p "=!_WRD! "为echo !_WRD!将导致：

this
is
a
test
that
works
于 2018-03-28T07:26:58.317 回答
0

FOR 循环限制记录在此处的标题“令牌”下：
https ://ss64.com/nt/for_f.html

“单个 FOR /F 命令永远不能解析超过 31 个令牌，要使用更多令牌需要使用多个 FOR 命令的解决方法。”

于 2019-11-12T14:42:36.287 回答