3

我需要获取有关外部应用程序的Webbrowser控件的滚动条（位置、大小、可见性）的信息，我尝试使用上一个问题中的GetScrollBarInfo函数，但该函数总是返回 false，我用另一个应用程序检查了这个函数，并且工作正常，但不适用于 IE 或 Webbrowser 控件。So how I can get information about the scrollbars of an Webbrowser control instance or the IE Webbrowser?

4

2 回答 2

7

您可以向外部应用程序的类窗口发送WM_HTML_GETOBJECT消息获取，然后使用您可以获取接口。 下面是 Delphi 中的一些示例代码："Internet Explorer_Server"IHtmlDocument2IServiceProviderIWebBrowser2

uses
  ActiveX, MSHTML;

type
  TObjectFromLResult = function(LRESULT: lResult; const IID: TIID;
    wParam: wParam; out pObject): HRESULT; stdcall;

function GetIEFromHWND(WHandle: HWND; var IE: IWebbrowser2): HRESULT;
var
  hInst: HWND;
  lRes: Cardinal;
  Msg: Integer;
  pDoc: IHTMLDocument2;
  ObjectFromLresult: TObjectFromLresult;
begin
  Result := S_FALSE;
  hInst := LoadLibrary('Oleacc.dll');
  @ObjectFromLresult := GetProcAddress(hInst, 'ObjectFromLresult');
  if @ObjectFromLresult <> nil then
  try
    Msg := RegisterWindowMessage('WM_HTML_GETOBJECT');
    SendMessageTimeOut(WHandle, Msg, 0, 0, SMTO_ABORTIFHUNG, 1000, lRes);
    Result := ObjectFromLresult(lRes, IHTMLDocument2, 0, pDoc);
    if Result = S_OK then
      (pDoc.parentWindow as IServiceprovider).QueryService(
        IWebbrowserApp, IWebbrowser2, IE);
  finally
    FreeLibrary(hInst);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Wnd, WndChild: HWND;
  IE: IWebBrowser2;
  Document: IHtmlDocument2;
  ScrollTop, ScrollLeft: Integer;
begin
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd = 0 then Exit;
  WndChild := FindWindowEX(Wnd, 0, 'Shell DocObject View', nil);
  if WndChild = 0 then Exit;
  WndChild := FindWindowEX(WndChild, 0, 'Internet Explorer_Server', nil);
  if WndChild = 0 then Exit;

  GetIEFromHWnd(WndChild, IE);
  if IE <> nil then
  begin
    ShowMessage(IE.LocationURL);
    Document := IE.Document as IHtmlDocument2;
    ScrollTop := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollTop;
    ScrollLeft := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollLeft;
    ShowMessage(Format('%d;%d', [ScrollTop, ScrollLeft]));

    // visible|hidden|scroll|auto|no-display|no-content
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowX);
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowY);
  end;
end;

编辑：当页面使用<!DOCTYPE>指令将 IE6 切换到严格标准兼容模式时使用document.documentElement. ( IHTMLDocument3) 在 pre-standard 模式下，body 表示可滚动区域，因此您可以使用 检索滚动位置 document.body.scrollTop。在标准模式下，HTML 元素是可滚动的，因此您应该使用document.documentElement.scrollTop.

如果document.documentElement.clientWidth <> 0将documentElement元素用于属性，则使用该body元素。
与滚动信息相关的有用属性还有clientHeight, scrollWidth, scrollHeight。

于 2012-03-20T01:30:03.523 回答
4

这是您如何知道滚动条是否可见的方法。为简洁起见，遗漏了一些错误检查。

LPDISPATCH      lpDispatch;
lpDispatch      = m_Browser.GetDocument();

IHTMLDocument2 *doc2 = NULL;
disp->QueryInterface(IID_IHTMLDocument2,(void**)&doc2);

IHTMLElement *lpBodyElement; 
IHTMLBodyElement *lpBody; 

doc2->get_body(&lpBodyElement); 
if ( lpBodyElement )
{
lpBodyElement->QueryInterface(IID_IHTMLBodyElement,(void**)&lpBody); 
if ( lpBody )
{
    BSTR bstrText; 
            pBody->get_scroll(&bstrText);
    lpBody->Release(); 
}
lpBodyElement->Release(); 
}
doc2->Release();

bstrText 的可能值为“yes”、“no”、“auto”（当页面内容超出客户区域时显示滚动条）

以下是您如何知道当前滚动位置的方法：

IHTMLElement2 *pElement = NULL;
hr = pBody->QueryInterface(IID_IHTMLElement2,(void**)&pElement);
ASSERT(SUCCEEDED(hr));
ASSERT( pElement );
long scroll_pos;
pElement->get_scrollTop( &scroll_pos);
于 2012-03-19T23:21:19.940 回答