19

我有一个存储过程需要设置一个保存点，以便在某些情况下，它可以撤消它所做的一切并将错误代码返回给调用者，或者接受/提交它并将成功返回给调用者。但是无论调用者是否已经开始交易，我都需要它来工作。该文档在这个主题上非常混乱。这是我认为可行的方法，但我不确定所有的后果。

问题是 - 这Stored Procedure (SP)是别人叫的。所以我不知道他们是否已经开始交易......即使我要求用户开始交易以使用我的SP，我仍然对正确使用Save Points......

我的 SP 将测试交易是否正在进行，如果没有，则以BEGIN TRANSACTION. 如果事务已经在进行中，它将改为创建一个保存点SAVE TRANSACTION MySavePointName，并保存我所做的事实。

然后，如果我必须回滚我的更改，如果我之前做了BEGIN TRANSACTION，那么我会ROLLBACK TRANSACTION。如果我做了保存点，那么我会ROLLBACK TRANSACTION MySavePointName。这种情况似乎效果很好。

这是我有点困惑的地方——如果我想保留我已经完成的工作，如果我开始了一个事务，我将执行COMMIT TRANSACTION。但是如果我创建了一个保存点呢？我试过COMMIT TRANSACTION MySavePointName了，但是调用者尝试提交它的事务并得到一个错误：

COMMIT TRANSACTION 请求没有对应的 BEGIN TRANSACTION。

所以我想知道 - 可以回滚保存点（有效：ROLLBACK TRANSACTION MySavePointName不会回滚调用者的事务）。但也许永远不需要“提交”它？它只是停留在那里，以防您需要回滚到它，但是一旦原始事务被提交（或回滚）就消失了？

如果有“更好”的方式来“嵌套”交易，也请说明一下。我还没有想出如何嵌套，BEGIN TRANSACTION但只能回滚或提交我的内部事务。似乎ROLLBACK总是会回滚到顶部事务，而COMMIT只是减量@@trancount。

4

3 回答 3

28

我相信我现在已经弄清楚了这一切，所以我会回答我自己的问题......

如果您想了解更多详细信息，我什至已经在博客上发布了我的发现： http://geekswithblogs.net/bbiales/archive/2012/03/15/how-to-nest-transactions-nicely---quotbegin-transactionquo​​t-vs- quotsave .aspx

所以我的 SP 以这样的方式开始，如果没有，则开始新事务，但如果已经在进行中，则使用保存点：

DECLARE @startingTranCount int
SET @startingTranCount = @@TRANCOUNT

IF @startingTranCount > 0
    SAVE TRANSACTION mySavePointName
ELSE
    BEGIN TRANSACTION
-- …

然后，当准备好提交更改时，您只需要在我们自己启动事务时提交：

IF @startingTranCount = 0
    COMMIT TRANSACTION

最后，回滚到目前为止的更改：

-- Roll back changes...
IF @startingTranCount > 0
    ROLLBACK TRANSACTION MySavePointName
ELSE
    ROLLBACK TRANSACTION
于 2012-03-16T21:11:43.480 回答
15

扩展布赖恩 B 的答案。

这可确保保存点名称是唯一的，并使用 SQL Server 2012 的新 TRY/CATCH/THROW 功能。

DECLARE @mark CHAR(32) = replace(newid(), '-', '');
DECLARE @trans INT = @@TRANCOUNT;

IF @trans = 0
    BEGIN TRANSACTION @mark;
ELSE
    SAVE TRANSACTION @mark;

BEGIN TRY
    -- do work here

    IF @trans = 0
        COMMIT TRANSACTION @mark;
END TRY
BEGIN CATCH
    IF xact_state() = 1 OR (@trans = 0 AND xact_state() <> 0) ROLLBACK TRANSACTION @mark;
    THROW;
END CATCH
于 2014-10-14T16:00:11.757 回答
4

我在我的存储过程中使用了这种类型的事务管理器：

    CREATE PROCEDURE Ardi_Sample_Test  
        @InputCandidateID INT  
    AS  
        DECLARE @TranCounter INT;  
        SET @TranCounter = @@TRANCOUNT;  
        IF @TranCounter > 0  
            SAVE TRANSACTION ProcedureSave;  
        ELSE  
            BEGIN TRANSACTION;  
        BEGIN TRY  

            /*
            <Your Code>
            */

            IF @TranCounter = 0  
                COMMIT TRANSACTION;  
        END TRY  
        BEGIN CATCH  
            IF @TranCounter = 0  
                ROLLBACK TRANSACTION;  
            ELSE  
                IF XACT_STATE() <> -1  
                    ROLLBACK TRANSACTION ProcedureSave;  

            DECLARE @ErrorMessage NVARCHAR(4000);  
            DECLARE @ErrorSeverity INT;  
            DECLARE @ErrorState INT;  
            SELECT @ErrorMessage = ERROR_MESSAGE();  
            SELECT @ErrorSeverity = ERROR_SEVERITY();  
            SELECT @ErrorState = ERROR_STATE();  

            RAISERROR (@ErrorMessage, @ErrorSeverity, @ErrorState);  
        END CATCH  
    GO
于 2017-02-03T19:16:07.280 回答