excel - 按名称引用excel工作表？

Question

我将工作表的名称作为字符串存储在变量中。如何在此工作表上执行一些操作？

我虽然我会做这样的事情：

nameOfWorkSheet = "test"
ActiveWorkbook.Worksheets(nameOfWorkSheet).someOperation()

我该怎么做？

Answer 1

有几个选项，包括使用您演示的方法、With 和使用变量。

我的首选是下面的选项 4：Dim类型变量Worksheet并存储工作表并调用变量上的方法或将其传递给函数，但是任何选项都有效。

Sub Test()
  Dim SheetName As String
  Dim SearchText As String
  Dim FoundRange As Range

  SheetName = "test"      
  SearchText = "abc"

  ' 0. If you know the sheet is the ActiveSheet, you can use if directly.
  Set FoundRange = ActiveSheet.UsedRange.Find(What:=SearchText)
  ' Since I usually have a lot of Subs/Functions, I don't use this method often.
  ' If I do, I store it in a variable to make it easy to change in the future or
  ' to pass to functions, e.g.: Set MySheet = ActiveSheet
  ' If your methods need to work with multiple worksheets at the same time, using
  ' ActiveSheet probably isn't a good idea and you should just specify the sheets.

  ' 1. Using Sheets or Worksheets (Least efficient if repeating or calling multiple times)
  Set FoundRange = Sheets(SheetName).UsedRange.Find(What:=SearchText)
  Set FoundRange = Worksheets(SheetName).UsedRange.Find(What:=SearchText)

  ' 2. Using Named Sheet, i.e. Sheet1 (if Worksheet is named "Sheet1"). The
  ' sheet names use the title/name of the worksheet, however the name must
  ' be a valid VBA identifier (no spaces or special characters. Use the Object
  ' Browser to find the sheet names if it isn't obvious. (More efficient than #1)
  Set FoundRange = Sheet1.UsedRange.Find(What:=SearchText)

  ' 3. Using "With" (more efficient than #1)
  With Sheets(SheetName)
    Set FoundRange = .UsedRange.Find(What:=SearchText)
  End With
  ' or possibly...
  With Sheets(SheetName).UsedRange
    Set FoundRange = .Find(What:=SearchText)
  End With

  ' 4. Using Worksheet variable (more efficient than 1)
  Dim MySheet As Worksheet
  Set MySheet = Worksheets(SheetName)
  Set FoundRange = MySheet.UsedRange.Find(What:=SearchText)

  ' Calling a Function/Sub
  Test2 Sheets(SheetName) ' Option 1
  Test2 Sheet1 ' Option 2
  Test2 MySheet ' Option 4

End Sub

Sub Test2(TestSheet As Worksheet)
    Dim RowIndex As Long
    For RowIndex = 1 To TestSheet.UsedRange.Rows.Count
        If TestSheet.Cells(RowIndex, 1).Value = "SomeValue" Then
            ' Do something
        End If
    Next RowIndex
End Sub

Answer 2

最好的方法是创建一个类型的变量Worksheet，分配工作表并在每次 VBA 隐式使用ActiveSheet.

这将帮助您避免最终会在程序变大时出现的错误。

例如，Range("A1:C10").Sort Key1:=Range("A2")当宏仅在一张纸上有效时，类似的东西很好。但是您最终将扩展您的宏以使用多个工作表，发现这不起作用，将其调整为ShTest1.Range("A1:C10").Sort Key1:=Range("A2")... 并发现它仍然不起作用。

这是正确的方法：

Dim ShTest1 As Worksheet
Set ShTest1 = Sheets("Test1")
ShTest1.Range("A1:C10").Sort Key1:=ShTest1.Range("A2")

Answer 3

为了扩展 Ryan 的答案，当您声明变量（使用 Dim）时，您可以使用 VBE 中的预测文本功能作弊，如下图所示。

如果它出现在该列表中，那么您可以将该类型的对象分配给变量。因此，正如 Ryan 指出的那样，不仅仅是一个工作表，还有一个图表、范围、工作簿、系列等等。

您将该变量设置为等于您要操作的对象，然后您可以调用方法，将其传递给函数等，就像 Ryan 在此示例中指出的那样。当涉及到集合与对象（图表或图表、范围或范围等）时，您可能会遇到一些障碍，但通过反复试验，您肯定会得到它。