playframework-2.0 - Play 2.0-RC3 -- 错误：无法找到或加载主类

Question

我正在尝试使用 Play 2.0 RC3。我已将框架解压缩到我的 Program Files 文件夹中，并将文件夹重命名为“play20”。我将该文件夹输入到我的 Windows 路径中。

每当我运行 Play 时，无论是play help还是play new，我总是得到Error: Could not find or load main class Files\play20\repository

我尝试进入文件夹本身而不是从路径运行，但我仍然得到相同的响应。

Answer 1

将文件夹复制到名称中没有空格的路径。“程序文件”的名称中有一个空格，这通常会导致问题。

作为建议，将播放文件夹复制到硬盘驱动器的根目录（C:、D:）

Answer 2

在 Windows 中运行 Play 2.0

下载后运行 Play 2.0 时出现问题。我将它安装在 c:\Program files\develop\play 中，这导致路径中的空白出现问题。

我根据这个 playframework google group entry中的 space-paths.patch 修补了 play-2.0\play.bat 和 play-2.0\framework\build.bat

在 play-2.0\play.bat 中替换代码

setlocal

set p=%~dp0
set p=%p:\=/%
set buildScript=%~dp0framework\build.bat
set additionalArgs=%*

if exist "conf\application.conf" goto existingApplication

:noApplication
java -Dsbt.ivy.home=%~dp0repository -Dplay.home=%~dp0framework -Dsbt.boot.properties="file:///%p%framework/sbt/play.boot.properties" -jar %~dp0framework\sbt\sbt-launch.jar %*

经过

setlocal enabledelayedexpansion

set p=%~dp0
set p=%p:\=/%

set fp=file:///!p: =%%20!
set buildScript="%~dp0framework\build.bat"
set additionalArgs=%*

if exist "conf\application.conf" goto existingApplication

:noApplication
java -Dsbt.ivy.home="%~dp0repository" -Dplay.home="%~dp0framework" -Dsbt.boot.properties="%fp%framework/sbt/play.boot.properties" -jar "%~dp0framework\sbt\sbt-launch.jar" %*

并在 play-2.0\framework\build.bat 中替换代码

set PLAY_VERSION="2.0"

if defined JPDA_PORT set DEBUG_PARAM="-Xrunjdwp:transport=dt_socket,server=y,suspend=n,address=%JPDA_PORT%"

set p=%~dp0
set p=%p:\=/%

java -Xms512M -Xmx1024M -Xss1M -XX:+CMSClassUnloadingEnabled -XX:MaxPermSize=256M %DEBUG_PARAM% -Dfile.encoding=UTF8 -Dplay.version="%PLAY_VERSION%" -Dsbt.ivy.home="%~dp0..\repository" -Dplay.home="%~dp0." -Dsbt.boot.properties="file:///%p%sbt/sbt.boot.properties" -jar "%~dp0sbt\sbt-launch.jar" %*

经过

setlocal enabledelayedexpansion

set PLAY_VERSION="2.0"

if defined JPDA_PORT set DEBUG_PARAM="-Xrunjdwp:transport=dt_socket,server=y,suspend=n,address=%JPDA_PORT%"

set p=%~dp0
set p=%p:\=/%
set fp=file:///!p: =%%20!


java -Xms512M -Xmx1024M -Xss1M -XX:+CMSClassUnloadingEnabled -XX:MaxPermSize=256M %DEBUG_PARAM% %JAVA_OPTS% -Dfile.encoding=UTF-8 -Dplay.version="%PLAY_VERSION%" -Dsbt.ivy.home="%~dp0..\repository" -Dplay.home="%~dp0." -Dsbt.boot.properties="%fp%sbt/sbt.boot.properties" -jar "%~dp0sbt\sbt-launch.jar" %*

:end
endlocal

这对我来说是一个新项目的诀窍。