3

我有一个现有的 XSLT 样式表，它采用 XML 并生成格式良好的 XHTML。我想制作此样式表的 XSL-FO 版本，以通过 Apache FOP 生成 PDF。我想知道的是：

是否有任何方便使用 xslt 模式的方法我需要学习做以下事情：

  • 复制一些未更改的节点
  • 复制大部分节点，但添加额外的属性

我知道我可以使用创建新节点

<xsl:element>

但是我还需要其他有用的东西吗？请注意，虽然我没有大量从一种 XSLT 格式复制到另一种格式，但我已经通过 XSLT 完成了大量的 XML-> XHTML，因此我熟悉该语言的大部分核心。

4

3 回答 3

8

您正在寻找的模式是“修改后的身份转换”。这种方法的基础是身份转换规则，它是下面样式表中的第一个模板规则。之后的每条规则都代表复制行为的一个例外。

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- By default, copy all nodes unchanged -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- But strip out <foo> elements (including their content) -->
  <xsl:template match="foo"/>

  <!-- For <bar> elements, strip out start & end tags, but leave content --> 
  <xsl:template match="bar">
    <xsl:apply-templates/>
  </xsl:template>

  <!-- For <bat> elements, insert an attribute and append a child --> 
  <xsl:template match="bat">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="id">123</xsl:attribute>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

对上述内容最不满意的是在最后一个模板规则中发现的逻辑重复。仅添加一个属性就需要很多代码。想象一下我们是否需要一堆这样的东西。这是另一种方法，可以让我们在想要覆盖的内容上更加精确：

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- By default, copy all nodes unchanged -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates mode="add-atts" select="."/>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

          <!-- By default, don't add any attributes -->
          <xsl:template mode="add-atts" match="*"/>

  <!-- For <bat> elements, insert an "id" attribute -->
  <xsl:template mode="add-atts" match="bat">
    <xsl:attribute name="id">123</xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

最后，这可以更进一步，为您可能想要进行的每种编辑使用不同的模式：

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- For <bat> elements, insert an "id" attribute -->
  <xsl:template mode="add-atts" match="bat">
    <xsl:attribute name="id">123</xsl:attribute>
  </xsl:template>

  <!-- Append <new-element/> to <bat> -->
  <xsl:template mode="append" match="bat">
    <new-element/>
  </xsl:template>

  <!-- Insert an element in <foo> content -->
  <xsl:template mode="insert" match="foo">
    <inserted/>
  </xsl:template>

  <!-- Add content before the <bar/> and <bat/> elements -->
  <xsl:template mode="before" match="bar | bat">
    <before-bat-and-bar/>
  </xsl:template>

  <!-- Add content only after <bat/> -->
  <xsl:template mode="after" match="bat">
    <after-bat/>
  </xsl:template>

  <!-- Here's the boilerplate code -->
  <!-- By default, copy all nodes unchanged -->
  <xsl:template match="@* | node()">
    <xsl:apply-templates mode="before" select="."/>
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates mode="add-atts" select="."/>
      <xsl:apply-templates mode="insert" select="."/>
      <xsl:apply-templates/>
      <xsl:apply-templates mode="append" select="."/>
    </xsl:copy>
    <xsl:apply-templates mode="after" select="."/>
  </xsl:template>

          <!-- By default, don't add anything -->
          <xsl:template mode="add-atts" match="*"/>
          <xsl:template mode="insert"   match="*"/>
          <xsl:template mode="append"   match="*"/>
          <xsl:template mode="before"   match="@* | node()"/>
          <xsl:template mode="after"    match="@* | node()"/>

</xsl:stylesheet>

在 XSLT 2.0 中，由于多模式模板规则，一些样板可以稍微简化：

          <!-- By default, don't add anything -->
          <xsl:template mode="add-atts
                              insert
                              append
                              before
                              after" match="@* | node()"/>

我有时会在同一个样式表中使用所有这些自定义模式，但通常我会根据需要懒惰地添加它们。

于 2009-06-05T17:15:51.047 回答
3

转换 XSLT 的最大障碍是输出名称空间前缀与转换中的实际 XSL 指令的前缀相同。如果您在 XSL 指令和输出中都使用“xsl:”，您的 XSLT 引擎将不知道它应该执行的 XSL 指令和它应该输出的 XSL 指令之间的区别，因此您的 XSLT 不会解析。也就是说，除非您使用命名空间别名：

<xsl:namespace-alias stylesheet-prefix="x" result-prefix="xsl"/>

该指令位于 内部<xsl:stylesheet />，允许您使用替代名称空间前缀在转换中编写结果标记。稍后，当创建输出文档时，您实际需要的前缀将被插入到别名的位置。因此，例如，这是一个在输出文档中生成模板的模板：

<xsl:template match="xsl:template[@match='title']>
   <x:template match="title>
      <x:apply-templates />
   </x:template>
</xsl:template>

这是一篇好文章：http ://www.xml.com/pub/a/2001/04/04/trxml/

于 2009-06-04T18:25:44.680 回答
0

过去我开发了 XSL-FO 样式表，然后使用Render-X FO2HTML 样式表将 XSL-FO 转换为 HTML。它将<block>元素转换为<div>、等。<inline><span>

我以前没有使用过它们，但您可以考虑尝试HTML2FO stylesheets。或者至少查看他们以借用一些想法。

由于 HTML 缺少 FO 提供的某些分页结构，因此它可能无法为您提供 XSL-FO 输出所需的全部内容，但可能会处理从 HTML 到 XSL-FO 元素/属性中的大部分转换逻辑文档的正文。

于 2009-08-21T11:50:20.110 回答