这是您正在寻找的 Muenchian 分组解决方案。
从您提供的原始 XML 开始，我认为按 AreaID 分组就足够了，但事实证明还需要按 UnitID 进行第二次分组。
这是我修改后的 XSLT 1.0 解决方案。它并不比原始解决方案复杂得多：
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
<xsl:key name="kPlanByArea" match="Plan"
use="@AreaID" />
<xsl:key name="kPlanByAreaAndUnit" match="Plan"
use="concat(@AreaID, ',', @UnitID)" />
<xsl:template match="/">
<xsl:apply-templates select="Root/Plans" />
</xsl:template>
<!-- main template -->
<xsl:template match="Plans">
<ol>
<!-- group by '{@AreaID}' (note the template mode!) -->
<xsl:apply-templates mode="area-group" select="
Plan[
generate-id()
=
generate-id(
key('kPlanByArea', @AreaID)[1]
)
]
">
<xsl:sort select="@AreaID" data-type="number" />
</xsl:apply-templates>
</ol>
</xsl:template>
<!-- template to output each '{@AreaID}' group -->
<xsl:template match="Plan" mode="area-group">
<li>
<xsl:value-of select="concat('Area ', @AreaID)" />
<ol>
<!-- group by '{@AreaID},{@UnitID}' -->
<xsl:apply-templates mode="unit-group" select="
key('kPlanByArea', @AreaID)[
generate-id()
=
generate-id(
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))[1]
)
]
">
<xsl:sort select="@UnitID" data-type="number" />
</xsl:apply-templates>
</ol>
</li>
</xsl:template>
<!-- template to output each '{@AreaID},{@UnitID}' group -->
<xsl:template match="Plan" mode="unit-group">
<li>
<xsl:value-of select="concat('Unit ', @UnitID)" />
<ol>
<xsl:apply-templates select="
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))/Part
">
<xsl:sort select="@UnitID" data-type="number" />
</xsl:apply-templates>
</ol>
</li>
</xsl:template>
<!-- template to output Parts into a list -->
<xsl:template match="Part">
<li>
<xsl:value-of select="concat('Part ', @ID, ' (', @Name ,')')" />
</li>
</xsl:template>
</xsl:stylesheet>
由于您的 XML 缺少它，我添加了一个 UnitID 来分组：
<Plan AreaID="1" UnitID="86">
<Part ID="8651" Name="zzz" />
</Plan>
这是输出：
<ol>
<li>Area 1
<ol>
<li>Unit 83
<ol>
<li>Part 9122 (foo)</li>
<li>Part 9126 (bar)</li>
</ol>
</li>
<li>Unit 86
<ol>
<li>Part 8650 (baz)</li>
<li>Part 8651 (zzz)</li>
</ol>
</li>
<li>Unit 95
<ol>
<li>Part 7350 (meh)</li>
</ol>
</li>
</ol>
</li>
<li>Area 2
<ol>
<li>Unit 26
<ol>
<li>Part 215 (quux)</li>
</ol>
</li>
</ol>
</li>
</ol>
由于您似乎很难使用 XSL 密钥，因此我尝试解释一下：
An<xsl:key>绝对等同于许多编程语言已知的关联数组（map、hash，无论你怎么称呼它）。这：
<xsl:key name="kPlanByAreaAndUnit" match="Plan"
use="concat(@AreaID, ',', @UnitID)" />
生成一个可以用 JavaScript 表示的数据结构，如下所示：
var kPlanByAreaAndUnit = {
"1,83": ['array of all <Plan> nodes with @AreaID="1" and @UnitID="83"'],
"1,86": ['array of all <Plan> nodes with @AreaID="1" and @UnitID="86"'],
/* ... */
"1,95": ['array of all <Plan> nodes with @AreaID="1" and @UnitID="95"']
};
调用访问数据结构的函数key()。所以，这个 XPath 表达式：
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))
是（再次在 JavaScript 中）的逻辑等价物：
kPlanByAreaAndUnit[this.AreaID + ',' + this.UnitID];
返回与给定键字符串匹配的所有节点的数组（更正确的节点集）（键始终是字符串）。这个节点集可以像 XSLT 中的任何其他节点集一样使用，即像您通过“传统”XPath 检索的节点集一样。这意味着您可以对其应用条件（谓词）：
<!-- first node only... -->
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))[1]
<!-- nodes that have <Part> children only... -->
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))[Part]
或将其用作 XPath 导航的基础：
<!-- the actual <Part> children of matched nodes... -->
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))/Part
等等。这也意味着我们可以将其用作 的“选择”表达式<xsl:apply-templates>，并且可以将其用作分组的基础。这将我们引向了上述样式表的核心（如果您已经将注意力集中在这个样式表上，那么您也已经了解了解决方案的其余部分）：
key('kPlanByArea', @AreaID)[
generate-id()
=
generate-id(
key('kPlanByAreaAndUnit', concat(@AreaID, ',', @UnitID))[1]
)
]
再次在 JavaScript 中，这可以表示为：
// the result will be a node-set, so we prepare an array
var selectedNodes = [];
// "key('kPlanByArea', @AreaID)"
var nodeSet = kPlanByArea[this.AreaID];
// "[...]" - the [] actually triggers a loop that applies
// the predicate expression to all nodes in the set, so we do:
for (var i = 0; i < nodeSet.length; i++) {
// use the current node for any calculations
var c = nodeSet[i];
if (
// if the current node === the *first* node in kPlanByAreaAndUnit...
generateId(c)
==
generateId(kPlanByAreaAndUnit[c.AreaID + ',' + c.UnitID][0])
) {
// ...include it in the resulting selection
selectedNodes.push(c)
}
}
表达式完成后，仅选择那些具有给定“AreaID，UnitID”组合的第一个节点 - 实际上我们已将它们分组到它们的“AreaID，UnitID”组合中。
将模板应用于此节点集会导致每个组合仅出现一次。然后我<xsl:template match="Plan" mode="unit-group">再次检索完整列表以实现每个组的完整输出。
我希望使用 JavaScript 来解释这个概念是一个有用的想法。