4

在我的应用程序中，我的用户可以将文件 (pdf/xls/doc) 导入表或将它们导出到文件夹。现在我想直接打开这些文件。

到目前为止，我能够： - 获得一个唯一的名称 - 将 blob 文件保存到生成的文件中 - 打开它

问题是我不知道如何删除（或更新）文件，之后文件将被用户关闭。

如果有人可以帮助我，我会很高兴:)

这是我的代码的快照：

procedure OpenTemporaryFile(AFileExtension: String; AKey: Integer;
            AMyConnection: TMyConnection);
     Var
       qrDocuments : TMyQuery ;
       TmpName,ExtName: string;
       TempFileName: TFileStream;
    begin
       //Generate an unique tmp file located into user temp folder
       TmpName:=  FileGetTempName('~SI');
       ExtName:= ChangeFileExt(TmpName, AFileExtension);
       //Change files extension so that Shellexecute will be able to open the file
       RenameFile(TmpName,ExtName );
       //Creating the FileStream (data is fetched from an blob field)
       TempFileName := TFileStream.Create(ExtName, fmOpenReadWrite );

       qrDocuments := TMyQuery.create(nil);
       try
        qrDocuments.Connection := AMyConnection;
        qrDocuments.Close;
        qrDocuments.SQL.Clear;
        qrDocuments.SQL.Text:='Select Id,FileName,Data from files where Id = :prId And Data IS NOT NULL';
        qrDocuments.ParamByName('prId').AsInteger := AKey;
        qrDocuments.open;
        TBlobField(qrDocuments.FieldByName('Data')).SaveToStream(TempFileName);
       finally
          TempFileName.Free;
          qrDocuments.free;
       end;
       ShellExecute(Application.Handle, 'open', Pchar(ExtName), '', '', SW_SHOWNORMAL);
       DeleteFile( ExtName);
    end;
4

7 回答 7

9

不幸的是，目前Remy Lebeau的这个答案有 4 个赞成票，当时该技术根本不适用于大多数应用程序。也许其中一个支持者可以发布一个代码片段，允许使用 Acrobat Reader 打开 PDF 文件，而该文件仍然使用FILE_FLAG_DELETE_ON_CLOSE标志打开？

无论如何，您可以在这里结合一些技巧以获得最佳效果：

  • 拥有您的应用程序使用的临时文件的内部列表。
  • 在程序关闭时，遍历临时文件列表并尝试删除它们。如果其中一些失败（因为它们仍然在外部应用程序中打开）使用gabr 给您的代码注册这些以在重新启动时删除。
  • 每当您需要一个新的临时文件时，首先遍历您的内部文件列表并尝试重用其中一个。仅当失败时才创建一个新文件（并将其名称添加到列表中）。

我更喜欢这种方法来注册所有文件以在重新启动时删除，因为我不确定您的应用程序可能会打开多少临时文件 - 也许可以注册的文件数量有限制MOVEFILE_DELAY_UNTIL_REBOOT？这是一个系统范围的资源，我只会谨慎使用。

于 2009-06-04T08:23:00.473 回答
7

一种可能性是将每个临时文件添加到系统启动期间删除的文件列表中。

在 Windows NT 平台上（自 Windows 2000 起），您可以调用MoveFileEx函数，并将第二个参数（目标）设置为 nil 并使用标志 MOVEFILE_DELAY_UNTIL_REBOOT。

在 Windows 9x 上，这要复杂得多。您必须编辑文件 %WINDIR%\wininit.ini 并将条目写入 [Rename] 部分。

MSDN 条目如何移动当前使用的文件描述了这两种技术。

函数 DSiMoveOnReboot（免费DSiWin32库的一部分）处理这两种操作系统。如果您传递一个空字符串作为第二个参数，它将在重新启动时删除源文件。

function DSiMoveOnReboot(const srcName, destName: string): boolean;
var
  wfile: string;
  winit: text;
  wline: string;
  cont : TStringList;
  i    : integer;
  found: boolean;
  dest : PChar;
begin
  if destName = '' then
    dest := nil
  else
    dest := PChar(destName);
  if DSiIsWinNT then
    Result := MoveFileEx(PChar(srcName), dest, MOVEFILE_DELAY_UNTIL_REBOOT)
  else
    Result := false;
  if not Result then begin
    // not NT, write a Rename entry to WININIT.INI
    wfile := DSiGetWindowsFolder+'\wininit.ini';
    if FileOpenSafe(wfile,winit,500,120{one minute}) then begin
      try
        cont := TStringList.Create;
        try
          Reset(winit);
          while not Eof(winit) do begin
            Readln(winit,wline);
            cont.Add(wline);
          end; //while
          if destName = '' then
            wline := 'NUL='+srcName
          else
            wline := destName+'='+srcName;
          found := false;
          for i := 0 to cont.Count - 1 do begin
            if UpperCase(cont[i]) = '[RENAME]' then begin
              cont.Insert(i+1,wline);
              found := true;
              break;
            end;
          end; //for
          if not found then begin
            cont.Add('[Rename]');
            cont.Add(wline);
          end;
          Rewrite(winit);
          for i := 0 to cont.Count - 1 do
            Writeln(winit,cont[i]);
          Result := true;
        finally cont.Free; end;
      finally Close(winit); end;
    end;
  end;
end; { DSiMoveOnReboot }
于 2009-06-03T18:07:42.597 回答
3

使用 Win32 API CreateFile() 函数打开文件，指定FILE_FLAG_DELETE_ON_CLOSE标志，然后将生成的句柄传递给 THandleStream 对象，以便您仍然可以使用 SaveToStream()。

此外，您的代码中有一个错误 - 您将错误的句柄类型传递给 ShellExecute()。它需要一个窗口句柄，但您传递的是文件句柄，更糟糕的是，您在释放 TFileStream 后访问文件句柄，从而关闭句柄。

于 2009-06-03T18:05:39.560 回答
1

也许您可以将它们存储在一些为您所知的文件夹中（例如 TEMP 文件夹中带有您的应用程序名称的子文件夹）并在用户下次加载您的应用程序时清除该文件夹的内容？或者您可以安装额外的清除实用程序并将其设置为在自动启动中运行。
关于重新启动后清除文件的另一个想法 - 您可以在启动时清除子文件夹中的所有内容，或者列出您创建的文件的最后修改时间、最后大小，将此列表存储在 XML 文件中，然后删除或更新比较您的内容包含该列表中文件详细信息的临时子文件夹？

于 2009-06-03T16:52:16.587 回答
1

如果我没记错的话，CreateFile 有一个标志，它告诉 Windows 应该在文件的最后一个句柄关闭后删除该文件。因此，正常创建文件，关闭并使用 share deny none 和上面提到的标志重新打开它。然后让外部应用程序打开它并自己关闭它。一旦外部应用程序关闭文件，这应该会导致 Windows 删除该文件。

（我没有试过这个。）

于 2009-06-03T18:09:06.743 回答
0

在类 Unix 操作系统中，通常的技巧是打开它并立即删除。它不会出现在目录中，但数据仍分配给保持它打开的进程。一旦它被关闭（或者进程死亡很好），文件系统就会回收空间。

这不是 hack，它已被记录和支持（将打开的文件句柄计为对文件的“引用”的结果，就像目录条目一样）。

也许Windows上有一些类似的技巧？我似乎记得 NTFS 支持对同一文件的多个引用（不，快捷方式不是那些）。如果是这样，删除文件但仍将最后一个引用作为临时资源挂起可能会起作用。

显然，我只是在这里猜测......

于 2009-06-03T17:03:27.540 回答
0

实际上，我们的应用程序在特定的临时文件夹中创建 de 文件。当应用程序关闭时，文件将被删除。如果应用程序未正确关闭，则下一次执行（关闭时）所有文件都将被删除。

此外，您可以启动后台进程来删除不再打开的文件。ShellExecute 返回一个句柄（在内部将此句柄关联到一个文件名）。该后台进程必须测试不存在的进程的句柄并删除关联的文件。

原谅英语不好。;-)

问候。

于 2009-06-04T08:37:42.737 回答