1

我正在使用 QCAR 库，并且在每一帧中都从库中获取相机帧。

我试图通过setImage在我的UIImageView* mCurFrameView. 起初这是可行的，我可以看到帧运行平稳，但 20 秒后它崩溃了。

有时我EXC_BAD_ACCESS上

int retVal = UIApplicationMain(argc, argv, nil, nil);

有时它只是 gdb 并暂停。

有时在他崩溃之前我得到

2012-02-24 15:59:15.726 QRAR_nextGen[226:707] Received memory warning.

这是我的代码：

-(void)SaveCurrentFrame:(UIImage*)image
{

        mCurFrameView.image = image;

}


- (void)renderFrameQCAR
{

   cout<<"I am starting"<<endl;


QCAR::State state = QCAR::Renderer::getInstance().begin();


QCAR::setFrameFormat(QCAR::RGB888, true);

const QCAR::Image *image = state.getFrame().getImage(1);// 0: YUV, 1: Grayscale image

if (image)
{
    const char *data = (const char *)image->getPixels();
    int width = image->getWidth(); int height = image->getHeight();

    colorSpace = CGColorSpaceCreateDeviceRGB();
    bitmapInfo = kCGBitmapByteOrderDefault;
    provider = CGDataProviderCreateWithData(NULL, data, width*height*3, NULL);
    intent = kCGRenderingIntentDefault;
    imageRef = CGImageCreate(width, height, 8, 8*3, width * 3, colorSpace, bitmapInfo,    provider, NULL, NO, intent);

    mCurFrame = [UIImage imageWithCGImage:imageRef];


    cout<<"I am waiting"<<endl;
   [self performSelectorOnMainThread:@selector(SaveCurrentFrame:) withObject:mCurFrame waitUntilDone:YES];

}

我尝试了几件事：显示 CALayer 以显示相机、释放、保留、自动释放、定义和不定义属性和合成。

如果有人可以帮助我，我将不胜感激。我正在失去理智。多谢。

4

3 回答 3

0

您没有释放（泄漏）每个 CGDataProvider，这意味着您将所有图像数据存储在内存中。在 performSelectorOnMainThread 之后尝试执行 CGDataProviderRelease(provider)。

于 2012-02-26T20:33:18.350 回答
0

也许你错过了这个：

   QCAR::Renderer::getInstance().end();

这是适用于 iPhone 4S/5 iOS 6 的片段

- (void)renderFrameIntoImage {
   QCAR::State state = QCAR::Renderer::getInstance().begin();
   QCAR::setFrameFormat(QCAR::GRAYSCALE, true);
   const QCAR::Image *image = state.getFrame().getImage(0); // 0: YUV, 1: Grayscale image
   const char *data = (const char *)image->getPixels();
   int width = image->getWidth(); int height = image->getHeight();
   CGColorSpace *colorSpace = CGColorSpaceCreateDeviceGray();
   CGBitmapInfo bitmapInfo = kCGBitmapByteOrderDefault;
   CGDataProvider *provider = CGDataProviderCreateWithData(NULL, data, width*height, NULL);
   CGColorRenderingIntent intent = kCGRenderingIntentDefault;
   CGImageRef imageRef = CGImageCreate(width, height, 8, 8, width * 1, colorSpace, bitmapInfo, provider, NULL, NO, intent);
   UIImage *myImage = [UIImage imageWithCGImage:imageRef];
   QCAR::Renderer::getInstance().end();
   UIImageWriteToSavedPhotosAlbum(myImage, nil, nil, NULL);
}

问候...

于 2013-04-10T22:50:19.223 回答
0

你有三个泄漏。

Release您必须为每个包含该单词的 CoreFoundation 方法调用一个方法Create。

  1. CGColorSpaceRelease(colorSpace);
  2. CGDataProviderRelease(provider);
  3. CGImageRelease(imageRef);

一种将 QCAR::Image 转换为 UIImage 的 C++ 方法

inline UIImage *imageWithQCARCameraImage(const QCAR::Image *cameraImage)
{
    UIImage *image = nil;

    if (cameraImage) {
        CGColorSpaceRef colorSpace = NULL;
        QCAR::PIXEL_FORMAT pixelFormat = cameraImage->getFormat();

        int bitsPerPixel = QCAR::getBitsPerPixel(pixelFormat);

        switch (pixelFormat) {
            case QCAR::RGB888:
                colorSpace = CGColorSpaceCreateDeviceRGB();
                break;
            case QCAR::GRAYSCALE:
                colorSpace = CGColorSpaceCreateDeviceGray();
                break;
            case QCAR::YUV:
            case QCAR::RGB565:
            case QCAR::RGBA8888:
            case QCAR::INDEXED:
                std::cerr << "Image format conversion not implemented." << std::endl;
                break;
            case QCAR::UNKNOWN_FORMAT:
                std::cerr << "Image format unknown." << std::endl;
                break;
        }

        float width = cameraImage->getWidth();
        float height = cameraImage->getHeight();
        int bytesPerRow = cameraImage->getStride();
        const void *baseAddress = cameraImage->getPixels();
        size_t totalBytes = QCAR::getBufferSize(width, height, pixelFormat);

        if (bitsPerPixel > 0 && colorSpace != NULL) {
            CGDataProviderRef provider = CGDataProviderCreateWithData(NULL,
                                                                      baseAddress,
                                                                      totalBytes,
                                                                      NULL);

            int bitsPerComponent = 8;
            CGBitmapInfo bitmapInfo = kCGBitmapByteOrderDefault | kCGImageAlphaNone;
            CGColorRenderingIntent renderingIntent = kCGRenderingIntentDefault;
            CGImageRef imageRef = CGImageCreate(width,
                                                height,
                                                bitsPerComponent,
                                                bitsPerPixel,
                                                bytesPerRow,
                                                colorSpace,
                                                bitmapInfo,
                                                provider,
                                                NULL,
                                                NO,
                                                renderingIntent);

            image = [UIImage imageWithCGImage:imageRef];
            CGColorSpaceRelease(colorSpace);
            CGDataProviderRelease(provider);
            CGImageRelease(imageRef);
        }
    }

    return image;
}
于 2015-04-06T13:40:45.327 回答