cuda - 如何使用 Thrust 从 int2 数组计算平均值

Question

我正在尝试计算包含点（x，y）的某个数组的平均值。
是否可以使用推力来找到表示为 (x,y) 点的平均点？thrust::device_vector<int>当每个单元格包含点的绝对位置时，我也可以将数组表示为 a ，这意味着i*numColumns + j尽管我不确定平均数是否代表平均单元格。
谢谢！

Answer 1

#include <iostream>
#include <thrust/device_vector.h>
#include <thrust/reduce.h>

struct add_int2 {
  __device__
  int2 operator()(const int2& a, const int2& b) const {
    int2 r;
    r.x = a.x + b.x;
    r.y = a.y + b.y;
    return r;
  }
};

#define N 20

int main()
{
  thrust::host_vector<int2> a(N);
  for (unsigned i=0; i<N; ++i) {
    a[i].x = i;
    a[i].y = i+1;
  }

  thrust::device_vector<int2> b = a;

  int2 init;
  init.x = init.y = 0;

  int2 ave = thrust::reduce(b.begin(), b.end(), init, add_int2());
  ave.x /= N;
  ave.y /= N;

  std::cout << ave.x << " " << ave.y << std::endl;
  return 0;
}

Answer 2

Keveman 的回答是正确的，我只是想添加一个需要代码的有用提示，所以我会把它放在这里而不是在评论中。

Thrust 1.5 添加了 lambda 占位符，这可以使 @keveman 的方法更加简单。而不是函子，只需定义operator+for int2，然后用_1 + _2lambda 占位符表达式替换函子的实例化。您还可以init用调用替换显式声明make_int2()（由 CUDA 提供）。注意：int2 operator+在 CUDA 代码示例 SDK 的“vector_math.h”标头中定义，但我在下面定义它以使其清楚（因为该文件不是 CUDA 的标准部分）。

#include <iostream>
#include <thrust/device_vector.h>
#include <thrust/reduce.h>

using namespace thrust::placeholders;

__device__
int2 operator+(const int2& a, const int2& b) {
  return make_int2(a.x+b.x, a.y+b.y);
}

#define N 20

int main()
{
  thrust::host_vector<int2> a(N);
  for (unsigned i=0; i<N; ++i) {
    a[i].x = i;
    a[i].y = i+1;
  }

  thrust::device_vector<int2> b = a;

  int2 ave = thrust::reduce(b.begin(), b.end(), make_int2(0, 0), _1 + _2);
  ave.x /= N;
  ave.y /= N;

  std::cout << ave.x << " " << ave.y << std::endl;
  return 0;
}