8

如何创建包含一组其他对象的数据类型。基本上，我正在执行以下代码：

(define-sort Set(T) (Array Int T))
(declare-datatypes () ((A f1 (cons (value Int) (b (Set B))))
  (B f2 (cons (id Int) (a  (Set A))))
 ))

但是 Z3 告诉我 A 和 B 的未知排序。如果我删除“设置”，它就像指南所说的那样工作。我试图改用 List 但它不起作用。任何人都知道如何使它工作？

4

2 回答 2

9

您正在解决一个经常出现的问题：如何混合数据类型和数组（作为集合、多集合或范围内的数据类型）？

如上所述，Z3 不支持在单个声明中混合数据类型和数组。一种解决方案是为混合数据类型 + 数组理论开发自定义求解器。Z3 包含用于开发自定义求解器的编程 API。

开发此示例以说明使用量词和触发器编码理论的能力和局限性仍然很有用。让我通过仅使用 A 来简化您的示例。作为一种解决方法，您可以定义一个辅助排序。但是，解决方法并不理想。它说明了一些公理“黑客”。它依赖于在搜索期间如何实例化量词的操作语义。

(set-option :model true) ; We are going to display models.
(set-option :auto-config false)
(set-option :mbqi false) ; Model-based quantifier instantiation is too powerful here


(declare-sort SetA)      ; Declare a custom fresh sort SetA
(declare-datatypes () ((A f1 (cons (value Int) (a SetA)))))

(define-sort Set (T) (Array T Bool))

然后定义 (Set A), SetA 之间的双射。

(declare-fun injSA ((Set A)) SetA)
(declare-fun projSA (SetA) (Set A))
(assert (forall ((x SetA)) (= (injSA (projSA x)) x)))
(assert (forall ((x (Set A))) (= (projSA (injSA x)) x)))

这几乎就是数据类型声明的内容。为了强制执行有根据，您可以将序数与 A 的成员相关联，并强制 SetA 的成员在有根据的排序中更小：

(declare-const v Int)
(declare-const s1 SetA)
(declare-const a1 A)
(declare-const sa1 (Set A))
(declare-const s2 SetA)
(declare-const a2 A)
(declare-const sa2 (Set A))

到目前为止的公理，a1 可以是它自己的一个成员。

(push)
(assert (select sa1 a1))
(assert (= s1 (injSA sa1)))
(assert (= a1 (cons v s1)))
(check-sat)
(get-model)
(pop)

我们现在将序数与 A 的成员相关联。

(declare-fun ord (A) Int)
(assert (forall ((x SetA) (v Int) (a A))
    (=> (select (projSA x) a)
        (> (ord (cons v x)) (ord a)))))
(assert (forall ((x A)) (> (ord x) 0)))

默认情况下，Z3 中的量词实例化是基于模式的。上面的第一个量化断言不会在所有相关实例上实例化。可以改为断言：

(assert (forall ((x1 SetA) (x2 (Set A)) (v Int) (a A))
    (! (=> (and (= (projSA x1) x2) (select x2 a))
        (> (ord (cons v x1)) (ord a)))
       :pattern ((select x2 a) (cons v x1)))))

像这样使用两种模式（称为多模式）的公理非常昂贵。它们为每对 (select x2 a) 和 (cons v x1) 生成实例化

以前的成员约束现在无法满足。

(push)
(assert (select sa1 a1))
(assert (= s1 (injSA sa1)))
(assert (= a1 (cons v s1)))
(check-sat)
(pop)

但是模型还不一定成型。该集合的默认值为“true”，这意味着该模型暗示在没有成员周期时存在成员周期。

(push)
(assert (not (= (cons v s1) a1)))
(assert (= (projSA s1) sa1))
(assert (select sa1 a1))
(check-sat)
(get-model)
(pop)

我们可以通过使用以下方法来逼近更忠实的模型来强制数据类型中使用的集合是有限的。例如，每当对集合 x2 进行成员资格检查时，我们都会强制该集合的“默认”值为“假”。

(assert (forall ((x2 (Set A)) (a A))
    (! (not (default x2))
        :pattern ((select x2 a)))))

或者，只要集合出现在数据类型构造函数中，它就是有限的

(assert (forall ((v Int) (x1 SetA))
    (! (not (default (projSA x1)))
        :pattern ((cons v x1)))))


(push)
(assert (not (= (cons v s1) a1)))
(assert (= (projSA s1) sa1))
(assert (select sa1 a1))
(check-sat)
(get-model)
(pop)

在包含其他公理的整个过程中，Z3 产生了“未知”的答案，而且产生的模型表明域 SetA 是有限的（单例）。因此，虽然我们可以修补默认值，但这个模型仍然不满足公理。它只满足公理模实例化。

于 2012-02-20T00:38:27.890 回答
2

Z3 不支持此功能。您可以在数据类型声明中使用数组，但它们不能包含对您声明的数据类型的“引用”。例如，可以使用(Set Int).

于 2012-02-18T18:27:58.323 回答