1

我需要为我的 Lazarus & Free Pascal GUI 程序添加一些功能 - 我还需要它来将文件从用户选择的目录复制到另一个目录。我有源目录的“选择源”TSelectDirectoryDialog 按钮 onclick 事件和目标目录的“选择目标”TSelectDirectoryDialog 按钮 onclick 事件。我有第三个按钮来进行从源到目标的复制。

到目前为止，我找到了复制文件和原始日期属性的 CopyFile，但它不会重新创建用户选择的源目录的任何子目录的子目录结构。实际上，我正在尝试将源目录复制到其他地方的新目录中。

我已经做到了这一点：

Public Vars :
DestDir, SourceDir : string
...
FS := TFileSearcher.Create;
FS.OnFileFound := @CopyTheFile;  // CopyTheFile is my own procedure 
FS.Search(SourceDir, '*', True);   
...

procedure TForm1.CopyTheFile(FileIterator: TFileIterator);
var
  DestinationName: String;
begin
  DestinationName := IncludeTrailingPathDelimiter(DestDir) + ExtractFileName(FileIterator.FileName);
  if not FileUtil.CopyFile(FileIterator.FileName, DestinationName, true) then
    ShowMessage(FileIterator.FileName + ' failed to copy');
end;

任何人都可以帮助我如何编写复制子目录及其文件的代码吗？我也在 Lazarus 论坛上问过这个问题：Lazarus Thread

非常感谢

泰德

4

1 回答 1

1

我非常高兴和自豪，并第一次为我自己的问题提供答案！我把整个事情都剥离了基础，不再阅读其他人的更复杂的例子（因为他们只是让我感到困惑）。我坚持使用Lazarus FileUtils Ref中列出的基本程序并想出了这个，它很有效。我需要构建一些错误检查和东西，但我现在拥有的是获取源目录的代码，在目标目录中重建它，然后将文件从原始目录复制到目标，使用完全免费的 Pascal 代码并且没有操作系统特定的语法。为了他人的利益，粘贴在下面。请添加任何建设性的评论，以使其更好、更快、更高效。谢谢。

procedure TForm1.Button3Click(Sender: TObject);
begin
  ProcessDir(SourceDir);
end;

procedure TForm1.ProcessDir(const SourceDirName: string);

var
  NoOfFilesFoundInSourceDir, i, NoOfFilesCopiedOK : integer;
  FilesFoundToCopy : TStringList;
  SourceDirectoryAndFileName, SubDirStructure, FinalisedDestDir, FinalisedFileName : string;

begin
  Memo1.Lines.Clear;
  SubDirStructure := '';
  FinalisedDestDir := '';
  NoOfFilesFoundInSourceDir := 0;
  NoOfFilesCopiedOK := 0;

  // Ensures the selected source directory is set as the directory to be searched
  // and then fina all the files and directories within, storing as a StringList.

  SetCurrentDir(SourceDirName);
  FilesFoundToCopy := FindAllFiles(SourceDirName, '*', True);
  NoOfFilesFoundInSourceDir := FilesFoundToCopy.Count;

  try
    for i := 0 to FilesFoundToCopy.Count -1 do
      begin
        Memo1.Lines.Add('File Index : '+IntToStr(i)+' File Name: '+FilesFoundToCopy.Strings[i]);
        SourceDirectoryAndFileName := ChompPathDelim(CleanAndExpandDirectory(FilesFoundToCopy.Strings[i]));

    // Determine the source sub-dir structure, from selected dir downwards

    SubDirStructure := IncludeTrailingPathDelimiter(ExtractFileDir(SourceDirectoryAndFileName));

    // Now concatenate the original sub directory to the destination directory and form the total path, inc filename
    // Note : Only directories containing files will be recreated in destination. Empty dirs are skipped.
    // Zero byte files are copied, though, even if the directory contains just one zero byte file.

    FinalisedDestDir := DestDir+SubDirStructure;
    FinalisedFileName := ExtractFileName(FilesFoundToCopy.Strings[i]);

    // Now create the destination directory structure, if it is not yet created. If it exists, just copy the file.

    if not DirPathExists(FinalisedDestDir) then
      begin
        if not ForceDirectories(FinalisedDestDir) then
          begin
            ShowMessage(FinalisedDestDir+' cannot be created.');
          end;
      end;

    // Now copy the files to the destination dir

    if not FileUtil.CopyFile(SourceDirectoryAndFileName, FinalisedDestDir+FinalisedFileName, true) then
      begin
        ShowMessage('Failed to copy file : ' + SourceDirectoryAndFileName)
      end
    else
    NoOfFilesCopiedOK := NoOfFilesCopiedOK + 1;
  end;
  finally
    FilesFoundToCopy.free;
  end;
  ShowMessage('Total files copied OK : ' + IntToStr(NoOfFilesCopiedOK));
end;
于 2012-02-22T15:27:50.703 回答