18

我想以通用方式将对象属性复制到另一个对象（如果目标对象上存在属性，我会从源对象复制它）。

我的代码使用ExpandoMetaClass可以正常工作，但我不喜欢这个解决方案。还有其他方法可以做到这一点吗？

class User {
    String name = 'Arturo'
    String city = 'Madrid'
    Integer age = 27
}

class AdminUser {
    String name
    String city
    Integer age
}

def copyProperties(source, target) {
    target.properties.each { key, value ->
        if (source.metaClass.hasProperty(source, key) && key != 'class' && key != 'metaClass') {
            target.setProperty(key, source.metaClass.getProperty(source, key))
        }
    }
}

def (user, adminUser) = [new User(), new AdminUser()]
assert adminUser.name == null
assert adminUser.city == null
assert adminUser.age == null

copyProperties(user, adminUser)
assert adminUser.name == 'Arturo'
assert adminUser.city == 'Madrid'
assert adminUser.age == 27
4

4 回答 4

32

我认为最好和明确的方法是使用InvokerHelper.setProperties方法

例子：

import groovy.transform.ToString
import org.codehaus.groovy.runtime.InvokerHelper

@ToString
class User {
    String name = 'Arturo'
    String city = 'Madrid'
    Integer age = 27
}

@ToString
class AdminUser {
    String name
    String city
    Integer age
}

def user = new User()
def adminUser = new AdminUser()

println "before: $user $adminUser"
InvokerHelper.setProperties(adminUser, user.properties)
println "after : $user $adminUser"

输出：

before: User(Arturo, Madrid, 27) AdminUser(null, null, null)
after : User(Arturo, Madrid, 27) AdminUser(Arturo, Madrid, 27)

注意：如果你想要更多的可读性，你可以使用 category

use(InvokerHelper) {
    adminUser.setProperties(user.properties) 
}
于 2014-05-10T16:43:20.347 回答
31

我认为您的解决方案非常好，并且在正确的轨道上。至少我觉得可以理解。

该解决方案的更简洁版本可能是......

def copyProperties(source, target) {
    source.properties.each { key, value ->
        if (target.hasProperty(key) && !(key in ['class', 'metaClass'])) 
            target[key] = value
    }
}

...但它并没有根本的不同。我正在迭代源属性，因此我可以使用这些值分配给目标:)。不过，它可能不如您的原始解决方案那么健壮，因为我认为如果目标对象定义了一个getAt(String)方法，它会中断。

如果你想变得花哨，你可以这样做：

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.properties*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

基本上，它首先计算两个对象之间的共同属性，然后复制它们。它也有效，但我认为第一个更简单，更容易理解:)

有时少即是多。

于 2012-01-31T00:47:14.357 回答
3

另一种方法是：

def copyProperties( source, target ) {
  [source,target]*.getClass().declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    a.intersect( b ).each {
      target."$it" = source."$it"
    }
  }
}

它获取公共属性（不是合成字段），然后将它们分配给目标

您还可以（使用此方法）执行以下操作：

def user = new User()

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.newInstance().with { tgt ->
      a.intersect( b ).each {
        tgt[ it ] = src[ it ]
      }
      tgt
    }
  }
}


def admin = propCopy( user, AdminUser )
assert admin.name == 'Arturo'
assert admin.city == 'Madrid'
assert admin.age == 27

因此，您将一个对象传递给该方法以从中复制属性，以及返回对象的类。然后该方法创建这个类的一个新实例（假设一个无参数构造函数），设置属性并返回它。

编辑 2

假设这些是 Groovy 类，您可以调用Map构造函数并设置所有公共属性，如下所示：

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.metaClass.invokeConstructor( a.intersect( b ).collectEntries { [ (it):src[ it ] ] } )
  }
}
于 2012-01-31T08:53:57.347 回答
1

即使源/目标类是不同的类型，Spring BeanUtils.copyProperties 也可以工作。http://docs.spring.io/autorepo/docs/spring/3.2.3.RELEASE/javadoc-api/org/springframework/beans/BeanUtils.html

于 2015-04-22T09:42:09.007 回答