5

我正在使用 xpath2 的 index-of 值返回排序后的节点序列中的 current() 的索引。使用 SAXON，排序后的节点序列是唯一的，但 index-of 返回两个值的序列。

这不会一直发生，只是偶尔发生，但不是出于任何我能找到的原因。有人可以解释发生了什么吗？

我已经根据例程给出这种奇怪行为的数据示例编写了一个最小示例。

源数据为：

<data>
<student userID="1" userName="user1"/>
<session startedOn="01/16/2012 15:01:18">
</session>
<session startedOn="11/16/2011 13:31:33">
</session>
</data>

我的 xsl 文档将会话节点放入根模板最顶部的排序序列 $orderd 中：

<xsl:template match="/">
<xsl:variable name="nodes" as="node()*" select="/data/session"></xsl:variable>
<xsl:variable name="orderd" as="node()*">
<xsl:for-each select="$nodes">
<xsl:sort select="xs:dateTime(xs:dateTime(concat(substring(normalize-space(@startedOn),7,4),'-',substring(normalize-space(@startedOn),1,2),'-',substring(normalize-space(@startedOn),4,2),'T',substring(normalize-space(@startedOn),12,8)))
)" order="ascending"/>
    <xsl:sequence select="."/>
</xsl:for-each>
</xsl:variable>

由于节点已经由@startOn 排序，但顺序相反，序列 $orderd 应该与文档排序序列 $nodes 相同，但顺序相反。

当我使用 for-each 语句创建输出时，我发现在使用 index-of 进行测试时，不知何故这两个节点被视为相同。

下面的代码用于输出数据（紧跟在上面的块之后）：

<output>
<xsl:for-each select="$nodes">
<xsl:sort select="position()" order="descending"></xsl:sort>
<xsl:variable name="index" select="index-of($orderd,current())" as="xs:integer*"></xsl:variable>
<xsl:variable name="pos" select="position()"></xsl:variable>        
<session reverse-documentOrder="{$pos}"  sortedOrder="{$index}"/>
</xsl:for-each>
</output>

正如输出（如下所示）所示，index-of 函数返回序列 (1,2)，这意味着它将两个节点视为相同。我检查了用于对值进行排序的表达式，它产生了不同且格式正确的日期时间字符串。

<output>
<session reverse=documentOrder="1"
        sortedOrder="1 2"/>
<session reverse-documentOrder="2"
        sortedOrder="1 2"/>
</output>
4

2 回答 2

4

不依赖于generate-id()函数，即 XSLT 函数，而不是 XPath 函数，可以编写一个index-of()对节点标识进行操作的简单函数：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="my:my">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    
    <xsl:variable name="vNum3" select="/*/*[3]"/>
    
    <xsl:variable name="vSeq" select="/*/*[1], /*/*[3], /*/*[3]"/>
    
 <xsl:template match="/">
   <xsl:sequence select="my:index-of($vSeq, $vNum3)"/>
 </xsl:template>
 
 <xsl:function name="my:index-of" as="xs:integer*">
  <xsl:param name="pSeq" as="node()*"/>
  <xsl:param name="pNode" as="node()"/>
  
  <xsl:for-each select="$pSeq">
    <xsl:if test=". is $pNode">
      <xsl:sequence select="position()"/>
    </xsl:if>
  </xsl:for-each>
 </xsl:function>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

返回所需的正确结果：

2 3

解释:is运算符的使用。

于 2012-01-30T14:14:38.007 回答
1

文档http://www.w3.org/TR/xpath-functions/#func-index-of说“序列 $seqParam中index-of的项目根据 eq 运算符的规则与 $srchParam 进行比较。类型的值xs:untypedAtomic 被比较，就好像它们是 xs:string 类型一样。”。因此，您正在尝试比较无类型的元素节点，这意味着它们被作为字符串进行比较，并且两个session元素都具有相同的仅空格字符串内容。这样，两者就被平等地比较了。

我不确定该建议什么，因为我不确定您想要实现什么，但我希望以上内容能够解释您得到的结果。

于 2012-01-30T12:50:07.370 回答