ocaml - 如何在 ocaml 中可视化/绘制自动机？

Question

我正在做自动机的组合。所以最后，我还想画出组合的自动机。那么在 ocaml 中是否有任何库？或者是否有为任何图形可视化工具编写的 ocaml 包装器？我已经用谷歌搜索了它，但对 ocaml 没有太多了解。对 ocamlgraph 有什么意见吗？我将在组合自动机中获得 100 多个状态。

Answer 1

使用ocamlgraph——它是一个图形库，可以为你生成一个 dot/graphviz 文件，但也可以做很多其他可能对处理你的自动机感兴趣的东西。该库可以进行定点、生成树、图搜索、查找强连通分量等。

这是一些带有标记边的有向图的完整示例+用于进行深度优先搜索的模块+用于创建点表示的模块：

(* representation of a node -- must be hashable *)
module Node = struct
   type t = int
   let compare = Pervasives.compare
   let hash = Hashtbl.hash
   let equal = (=)
end

(* representation of an edge -- must be comparable *)
module Edge = struct
   type t = string
   let compare = Pervasives.compare
   let equal = (=)
   let default = ""
end

(* a functional/persistent graph *)
module G = Graph.Persistent.Digraph.ConcreteBidirectionalLabeled(Node)(Edge)

(* more modules available, e.g. graph traversal with depth-first-search *)
module D = Graph.Traverse.Dfs(G)

(* module for creating dot-files *)
module Dot = Graph.Graphviz.Dot(struct
   include G (* use the graph module from above *)
   let edge_attributes (a, e, b) = [`Label e; `Color 4711]
   let default_edge_attributes _ = []
   let get_subgraph _ = None
   let vertex_attributes _ = [`Shape `Box]
   let vertex_name v = string_of_int v
   let default_vertex_attributes _ = []
  let graph_attributes _ = []
end)

有了它，您可以编写程序；例如这样的：

(* work with the graph ... *)
let _ =
   let g = G.empty in
   let g = G.add_edge_e ...
   ...
   let file = open_out_bin "mygraph.dot" in
   let () = Dot.output_graph file g in
   ...
   if D.has_cycle g then ... else ...

Answer 2

我只是将自动机作为文本写入文件（以适合 graphviz 的格式），然后针对该文件运行 graphviz。