5

在链接http://www.ccs.neu.edu/home/ryanc/macro-stepper/tutorial.html上有使用宏步进器的说明。

但是，当我要尝试它时，我无法在非零的定义中获得 myor 的第二次扩展？功能，只有第一个。另外，我没有“上学期”和“下学期”按钮。

所以我的问题是：我必须如何配置宏步进器才能获得第二次扩展，就像在教程中一样？

4

2 回答 2

6

我假设您的源程序看起来像这样：

#lang racket
(define-syntax myor
  (syntax-rules ()
    [(myor e) e]
    [(myor e1 . es)
     (let ([r e1]) (if r r (myor . es)))]))
(define (nonzero? r)
  (myor (negative? r)
        (positive? r)))

短篇小说：暂时使用syntax-case而不是syntax-rules；似乎有一些与宏步进器和语法规则相关的错误。我已向 Racket 开发人员发送了一份错误报告，因此希望这将很快得到修复。上述程序的语法案例版本如下所示。

#lang racket

(define-syntax (myor stx)
  (syntax-case stx ()
    [(_ e) #'e]
    [(_ e1 . es)
     #'(let ([r e1]) (if r r (myor . es)))]))

(define (nonzero? r)
  (myor (negative? r)
        (positive? r)))

下面是更长的故事......

当我在 5.2.1 的预发行版下运行您的程序时，我在宏步进器中看到以下内容，宏隐藏设置为“标准”：

(module anonymous-module racket
  (#%module-begin
   (define-syntax myor
     (syntax-rules () [(myor e) e] [(myor e1 . es) (let ([r e1]) (if r r (myor . es)))]))
   (define (nonzero? r)
     (let:26 ([r:26 (negative? r)]) (if:26 r:26 r:26 (myor:26 (positive? r)))))))

看起来不对。它将myor的一种用途扩展到if的用途。很奇怪！

让我们看看在 Racket 5.2 下是什么样子的……

(module anonymous-module racket
  (#%module-begin
   (define-syntax myor
     (syntax-rules () [(myor e) e] [(myor e1 . es) (let ([r e1]) (if r r (myor . es)))]))
   (define (nonzero? r) (let ([r (negative? r)]) (if r r (myor (positive? r)))))))

啊。好的，我可以确认我看到了与您在 Racket 5.2 以及预发布版本中看到的相同的问题。

该错误似乎与“宏隐藏”功能的行为有关，当它设置为标准时，它试图不让你用完整的扩展压倒你。如果您将其设置为“禁用”，您将看到宏调试器将以其完整、未修饰的荣耀显示扩展，并且它确实包括我们期望看到的扩展：

(module anonymous-module racket
  (#%module-begin
   (define-syntaxes (myor)
     (lambda (x)
        ; ... I'm omitting the content here: it's way too long.
     ))
   (define-values:20 (nonzero?)
     (lambda:21 (r) (let-values:22 (((r) (#%app:23 negative? r))) (if r r (#%app:24 positive? r)))))))

我会写一份错误报告并将其发送给 Racket 开发人员。

如果您使用syntax-case编写宏，而不是syntax-rules，它似乎与 Macro Stepper 一起工作得更好。

#lang racket

(define-syntax (myor stx)
  (syntax-case stx ()
    [(_ e) #'e]
    [(_ e1 . es)
     #'(let ([r e1]) (if r r (myor . es)))]))

(define (nonzero? r)
  (myor (negative? r)
        (positive? r)))

当我逐步完成时，它似乎工作得更好。所以无论是什么触发了这个错误，它似乎都是与 Macro Stepper 和syntax-rules的一些交互。因此，请尝试改用语法大小写。

于 2012-01-23T02:53:08.503 回答
1

它对我有用，无需做任何额外的事情。尝试使用最新版本的球拍，也尝试从菜单中选择不同的语言，并确保debugging选择了您选择的语言。

于 2012-01-22T15:46:09.247 回答