可以通过高阶函数对无类型 lambda 演算中的各种类型进行编码。
Examples:
zero = λfx. x
one = λfx. fx
two = λfx. f(fx)
three = λfx. f(f(fx))
etc
true = λtf. t
false = λtf. f
tuple = λxyb. b x y
null = λp. p (λxy. false)
我想知道是否有任何研究涉及嵌入其他不太传统的类型。如果有一些定理断言可以嵌入任何类型，那就太好了。也许有一些限制，例如只能嵌入 kind * 类型。
如果确实可以表示不太传统的类型，那么看到一个例子会很棒。我特别热衷于看看 monad 类型类的成员长什么样。
几乎可以表示您想要的任何类型。但是由于每种类型的单子操作的实现方式不同，因此不可能编写>>=一次并使其适用于每个实例。
但是，您可以编写依赖于类型类实例证据的泛型函数。考虑e这里是一个元组，其中fst e包含一个“绑定”定义，并snd e包含一个“返回”定义。
bind = λe. fst e -- after applying evidence, bind looks like λmf. ___
return = λe. snd e -- after applying evidence, return looks like λx. ___
fst = λt. t true
snd = λt. t false
-- join x = x >>= id
join = λex. bind e x (λz. z)
-- liftM f m1 = do { x1 <- m1; return (f x1) }
-- m1 >>= \x1 -> return (f x1)
liftM = λefm. bind e m (λx. return e (f x))
然后，您必须为 Monad 的每个实例定义一个“证据元组”。请注意，我们定义的方式bind和return：它们的工作方式与我们定义的其他“通用” Monad 方法一样：必须首先为它们提供Monad-ness 的证据，然后它们按预期运行。
我们可以表示Maybe为一个接受 2 个输入的函数，第一个是执行的函数，如果它是Just x，第二个是一个值，如果它是 Nothing 则替换它。
just = λxfz. f x
nothing = λfz. z
-- bind and return for maybes
bindMaybe = λmf. m f nothing
returnMaybe = just
maybeMonadEvidence = tuple bindMaybe returnMaybe
列表类似，将列表表示为其折叠功能。因此，列表是一个接受 2 个输入的函数，一个“cons”和一个“empty”。然后它foldr myCons myEmpty在列表上执行。
nil = λcz. z
cons = λhtcz. c h (t c z)
bindList = λmf. concat (map f m)
returnList = λx. cons x nil
listMonadEvidence = tuple bindList returnList
-- concat = foldr (++) []
concat = λl. l append nil
-- append xs ys = foldr (:) ys xs
append = λxy. x cons y
-- map f = foldr ((:) . f) []
map = λfl. l (λx. cons (f x)) nil
Either也很简单。将任一类型表示为一个接受两个函数的函数：如果它是 a 则应用一个函数，如果它是 a 则Left另一个应用Right。
left = λlfg. f l
right = λrfg. g r
-- Left l >>= f = Left l
-- Right r >>= f = f r
bindEither = λmf. m left f
returnEither = right
eitherMonadEvidence = tuple bindEither returnEither
不要忘记，函数本身 (a ->)就形成了一个单子。lambda 演算中的所有内容都是一个函数……所以……不要想得太难。;) 直接来自Control.Monad.Instances的源代码
-- f >>= k = \ r -> k (f r) r
bindFunc = λfkr. k (f r) r
-- return = const
returnFunc = λxy. x
funcMonadEvidence = tuple bindFunc returnFunc
您正在将类型级别与值级别混淆。在无类型的 lambda 演算中没有单子。可以有单子操作（值级别），但不能有单子（类型级别）。但是，操作本身可以相同，因此您不会失去任何表达能力。所以这个问题本身并没有真正的意义。
好吧，我们已经有了元组和布尔值，因此我们可以Either基于它来表示并反过来表示任何非递归求和类型：
type Either a b = (Bool, (a, b))
type Maybe a = Either () a
Maybe 是 Monad 类型类的成员。转换为 lambda 表示法留作练习。