3

我有一个语句级触发器，只要在表（称为客户）上执行 INSERT UPDATE 或 DELETE 操作就会触发。我想显示一条消息（到 DBMS_OUTPUT），其中包含插入/更新/删除的行数。

我只想为每个触发语句发送一条消息，例如“4 行已插入客户表”。

如何从 INSIDE 触发器声明中访问受触发语句影响的行数，即下面代码中的 XXX：

CREATE OR REPLACE TRIGGER customer_changes_trigger_2
AFTER INSERT OR UPDATE OR DELETE ON customers

DECLARE
v_operation   VARCHAR(10);
v_number_rows NUMBER;


BEGIN

v_number := XXX;

IF INSERTING THEN
   v_operation := 'inserted';
END IF;

IF UPDATING THEN
   v_operation := 'updated';
END IF;

IF DELETING THEN
   v_operation := 'deleted';
END IF;

DBMS_OUTPUT.PUT_LINE
          (v_number_rows|| ' rows were ' || v_operation || ' from customers.');
END;

在文档中找不到任何内容，感谢您的帮助！

4

2 回答 2

4

一种方法是使用全局变量来跟踪行数，因为没有其他方法可以从语句级触发器中获取行数。然后，您将需要三个触发器......一个语句级别在运行语句之前初始化变量，一个行级别为每行添加一个变量，一个语句级别使用您希望的行数。首先，设置变量和一些帮助它的过程：

create or replace package PKG_ROWCOUNT is
  NUMROWS   number;

  procedure INIT_ROWCOUNT;

  procedure ADD_ONE;

  function GET_ROWCOUNT
    return number;
end PKG_ROWCOUNT;
/

create or replace package body PKG_ROWCOUNT as
  procedure INIT_ROWCOUNT is
  begin
    NUMROWS := 0;
  end;

  procedure ADD_ONE is
  begin
    NUMROWS := Nvl(NUMROWS, 0) + 1;
  end;

  function GET_ROWCOUNT
    return number is
  begin
    return NUMROWS;
  end;
end PKG_ROWCOUNT;
/

初始化变量的第一个触发器：

create or replace trigger CUSTOMER_CHANGES_TRIGGER_1
  before insert or update or delete
  on CUSTOMERS
begin
  PKG_ROWCOUNT.INIT_ROWCOUNT;
end;

每行更新的第二个：

create or replace trigger CUSTOMER_CHANGES_TRIGGER_2
  after insert or update or delete
  on CUSTOMERS
  for each row
begin
  PKG_ROWCOUNT.ADD_ONE;
end;
/

第三个显示总数：

create or replace trigger CUSTOMER_CHANGES_TRIGGER_3
  after insert or update or delete
  on CUSTOMERS
begin
   Dbms_output.
   PUT_LINE(PKG_ROWCOUNT.GET_ROWCOUNT || ' rows were affected.');
end;
于 2012-01-07T16:45:33.053 回答
-1

我不确定 100 美元是否可以在AFTER触发器体内使用，但您可以尝试检查sql%rowcount

于 2012-01-07T15:04:04.680 回答