2

这个问题指的是这个问题以及它在stackoverflow上发布的公认答案。

我对Windows API编程感到不舒服。

探索Topografix的EasyGPS处理剪贴板操作的方式，我发现它使用了一种名为wich 的自定义剪贴板格式GPX，实际上是纯 XML 文本（准确地说是GPX）。不包括使用 Clipboard.AsText。

我在这个阶段绊倒了：

program ProbeClipboard;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Windows,
  ClipBrd;

var
  CF_GPX: Cardinal;
  ClipboardData: THandle;

begin
  CF_GPX:=RegisterClipboardFormat('GPX');

  if ClipBoard.HasFormat(CF_GPX) then
  begin
    Writeln('GPX format available in clipboard');
    //
    OpenClipboard(0);

    ClipboardData := GetClipboardData(CF_GPX);

    if ClipboardData = 0 then
      raise Exception.Create('Clipboard data Error');

    /// How to use GlobalLock and GlobalUnLock
    /// so that I can paste the Clipboard data
    /// to a TMemo instance for example

    CloseClipboard;
  end;
end.

请帮我修复那个程序。

4

1 回答 1

5

我会这样写：

program ProbeClipboard;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Windows,
  ClipBrd;

var
  CF_GPX: Cardinal;
  ClipboardData: Windows.HGLOBAL;
  Ptr: Pointer;
  Size: DWORD;

begin
  CF_GPX := RegisterClipboardFormat('GPX');

  Clipboard.Open;
  try
    if Clipboard.HasFormat(CF_GPX) then
    begin
      Writeln('GPX format available in clipboard');

      ClipboardData := Clipboard.GetAsHandle(CF_GPX);
      if ClipboardData=0 then
        RaiseLastOSError;

      Ptr := Windows.GlobalLock(ClipboardData);
      if Ptr=nil then
        RaiseLastOSError;

      try
        Size := Windows.GlobalSize(ClipboardData);

        //Ptr now points to a memory block of Size bytes 
        //containing the clipboard data
      finally
        Windows.GlobalUnlock(ClipboardData);
      end;
    end;
  finally
    Clipboard.Close;
  end;
end.

请注意，我移动了剪贴板Open命令，该命令将剪贴板锁定在CF_GPX格式测试之外。那是为了避免代码中存在的竞争条件。在您的代码中，剪贴板可以在HasFormat调用和OpenClipboard调用之间进行修改。

我也Clipboard专门使用了这个类。这个类有你需要的一切，你不需要使用原始的 Win32 剪贴板 API。

我什至输入了错误检查！

于 2012-01-01T20:20:43.527 回答