haskell - Repa --- 如何创建一个 Read 实例？

Question

最好的制作方法是什么

type Configuration = Array DIM1 (Double, Double, Double)

读的一个实例？所以后来我可以得出

data SimulationData = SD Configuration Double StdGen Int

也是 Read 的一个实例。

Answer 1

这样的实例将是孤立实例，您通常应该避免使用它。但是，编写它相当简单：

{-# LANGUAGE TypeOperators #-}

import Data.Array.Repa (Array, Shape, Elt, Z(..), (:.)(..))
import qualified Data.Array.Repa as R

instance Read Z where
  readsPrec _ r = do
    ("Z", s) <- lex r
    return (Z, s)

instance (Read tail, Read head) => Read (tail :. head) where
  readsPrec d =
    readParen (d > prec) $ \r -> do
      (tl, s) <- readsPrec (prec + 1) r
      (":.", t) <- lex s
      (hd, u) <- readsPrec (prec + 1) t
      return (tl :. hd, u)
    where prec = 3

instance (Shape sh, Read sh, Elt a, Read a) => Read (Array sh a) where
  readsPrec d =
    readParen (d > app) $ \r -> do
      ("Array", s) <- lex r
      (sh, t) <- readsPrec (app + 1) s
      (xs, u) <- readsPrec (app + 1) t
      return (R.fromList sh xs, u)
    where app = 10

如果使用StandaloneDeriving扩展，前两个实例可以简化：

deriving instance Read Z
deriving instance (Read tail, Read head) => Read (tail :. head)

这些实例可能应该在 repa 本身；我只是基于Text.Show和 repa 的show输出中给出的示例实例。我建议在 repa 的bug tracker上提出功能请求，并暂时将这些实例放入程序的模块中（除非您想完全避免孤立实例，在这种情况下，您必须完全以另一种方式解决问题）。

---

也就是说，您可能应该考虑简单地将数据转换为列表（使用toList）并使用它；它避免了孤儿实例，并且不应该有任何缺点。如果您更感兴趣的是用代码处理数据而不是人类可读的数据，那么您可能还想考虑使用像谷物这样的“真正的”序列化库；Read通常被认为是相当有限的用途。