26

如果您熟悉 iTerm2 应用程序，您就会知道您可以像 vim 一样拆分视图，并且不活动的视图会“变暗”。

我通常在 vim 中使用三个垂直拆分视图，例如，通过将背景颜色设置为较暗的色调来使不活动的视图变暗会很好。

有没有办法做到这一点？

4

4 回答 4

21

我想出了以下解决方案（使用'colorcolumn'并取消设置'cursorline'）：

" Dim inactive windows using 'colorcolumn' setting
" This tends to slow down redrawing, but is very useful.
" Based on https://groups.google.com/d/msg/vim_use/IJU-Vk-QLJE/xz4hjPjCRBUJ
" XXX: this will only work with lines containing text (i.e. not '~')
function! s:DimInactiveWindows()
  for i in range(1, tabpagewinnr(tabpagenr(), '$'))
    let l:range = ""
    if i != winnr()
      if &wrap
        " HACK: when wrapping lines is enabled, we use the maximum number
        " of columns getting highlighted. This might get calculated by
        " looking for the longest visible line and using a multiple of
        " winwidth().
        let l:width=256 " max
      else
        let l:width=winwidth(i)
      endif
      let l:range = join(range(1, l:width), ',')
    endif
    call setwinvar(i, '&colorcolumn', l:range)
  endfor
endfunction
augroup DimInactiveWindows
  au!
  au WinEnter * call s:DimInactiveWindows()
  au WinEnter * set cursorline
  au WinLeave * set nocursorline
augroup END

在我的（当前）点文件中查看它：https ://github.com/blueyed/dotfiles/blob/master/vimrc#L351

更新 我已经创建了一个插件：https ://github.com/blueyed/vim-diminactive

于 2012-09-20T19:27:46.517 回答
13

把它作为一个新的答案扔出去。https://github.com/TaDaa/vimade淡化非活动缓冲区，保留语法突出显示，还可以淡化符号。我是作者，但我认为这可能对某些人有用，作为一种较新的选择。支持 nvim 和 vim8、256 色终端、termguicolors 和 gui。

于 2019-01-07T21:08:56.940 回答
6

在 neovim(v0.2.1) 中，以下配置将使非活动窗格变暗：

hi ActiveWindow ctermbg=16 | hi InactiveWindow ctermbg=233
set winhighlight=Normal:ActiveWindow,NormalNC:InactiveWindow
于 2018-01-18T21:31:45.693 回答
1

根据您的描述更改背景颜色将需要不同 Vim 窗口的不同颜色方案。据我所知，这是不可能的，因为它是一个全局设置（请参阅几天前的这个答案）。

作为激活窗口的视觉辅助，我发现状态行通常就足够了。hi StatusLine活动窗口 ( ) 和任何非活动窗口 ( )的突出显示组是不同的hi StatusLineNC。您可以选择它们之间形成鲜明对比的配色方案，也可以编辑您最喜欢的配色方案。

于 2011-12-07T13:22:04.247 回答